MISCELLANEOUS FIXES
========================

The lex type for one of our auxiliaries 'veln' was inheriting the
required types to be able to take inflectional morphology, when we are
implementing it as an irregular verb with separate lex types for each
form. One we removed the types that made it an inflecting verb and
removed the INFLECTING.FORM-FLAG, we were able to parse the sentence
bellow. This also highlighted an assumption our grammar makes, which
is that the lexical rules which generate the finite form of the verb
also constrain the verb to present tense. While this happens to be
true for all verbs that use these inflectional rules for the current
phenomena we have implemented analyses for, these two linguistic
functions do not necessary coincide and should be abstracted out. For
instance, this would yield problems if any of our auxiliaries involved
in tense constructions happened to have regular morphology -- as it is
they happen not to.


Source: {a:218}
Vetted: t
Judgment: g
Phenomena: {tam}
Ikh vel shraybn.
Ikh vel shrayb-n.
1SG.NOM shall;1SG write-INF.
I shall write.


We also finally added lex types and respective entries for all the
specific finite forms of the auxiliaries and copulas, which do not
have regular inflectional morphology. Once these constraints were
added our grammar stopped overgenerating with the incorrect forms of
the auxiliaries, such this:


Source: author based on {a:217}
Vetted: f
Judgment: u
Phenomena: {agreement}
Ikh hot geshribn.
Ikh hot ge-shrayb-n.
1SG.NOM have;3SG PP-write-PP.
I have written.


We also fixed up the incorrect semantics for adjectives, adverbs and
predicative adjectives. In the case of adjectives and adverbs, this
was due to the lex-rule incorrectly inheriting from
intersective-mod-lex rather than the lex-type, and in the case of
predicative adjectives, this was because we were not identifying the
XARG with ARG1.


Source: author
Vetted: f
Judgment: g
Phenomena: {adverb, word order}
Gut zingt dos kind.
Gut zing-t dos kind.
well sing-1SG DEF.NOM.N child.
The child sings well.


Another thing that emerged was that we were identifying sentences with
an adverb preceding verb initial word order as an adverb modifying an
interrogative clause. This however could also be a topicalized adverb
from a VOS clause however, and we were in fact getting two parses
corresponding to these cases. Due to this inherent ambiguity, we
suspect that this word order would only have an interrogative
interpretation with accompanying rising intonation. This meant that we
changed the test suite example to reflect the new analysis, and also
that we needed to rule out the parse corresponding to the
interrogative reading. We did this by enforcing that the q-clause-rule
can only apply to modified phrases that attached to the right:


q-clause-rule := unary-phrase & interrogative-clause &
  [ SYNSEM.LOCAL.CAT [ MC +,
                       HEAD #head,
                       VAL #val ],
    ARGS < [ SYNSEM [ MODIFIED notmod-or-rmod,
                      LOCAL.CAT [ MC na,
                                  HEAD #head & verb & [ FORM finite,
                                                        MOD < > ],
                                  VAL #val & [ SUBJ < >,
                                               COMPS < >,
                                               SPR < >,
                                               SPEC < > ] ] ] ] > ].


Modals
========================

In Yiddish the modal that functions similarly to 'can' in English,
behaves in a largely similar way. It functions as an auxiliary verb in
finite form, which takes a verb phrase headed by a nonfinite verb as
its complement:


Source: a:246
Vetted: t
Judgment: g
Phenomena: {word order}
Du kenst zingen.
Du ken-st zing-en.
2SG.NOM can-2SG sing-INF.
You can sing.


In order to implement this we defined a new verb type that inherits
from verb-lex and trans-first-arg-raising-lex-item-1 called
subj-raise-aux-pred since this wasn't already generated by the
matrix. The ARG-ST value of the type identifies the first argument
with the subject and constrains it to be noun-headed. The second
argument in ARG-ST is identified with the COMPS list and is further
constrained to agree with the case of the first argument.

We then just had to create the appropriate lex type ken-aux-lex, which
in addition to inheriting from subj-raise-aux-pred, also constrained
the head of its complement to be nonfinite.

ken-aux-lex := subj-raise-aux-pred & form-rule-dtr & regular-verb-lex &
	[ SYNSEM.LOCAL [ CAT.VAL.COMPS.FIRST.LOCAL.CAT.HEAD.FORM nonfinite ] ].

subj-raise-aux-pred := verb-lex & trans-first-arg-raising-lex-item-1 & norm-sem-lex-item &
  [ SYNSEM.LOCAL [ CAT.VAL [ SPR < >,
                             SPEC < >,
                             COMPS < #comps >,
                             SUBJ < #subj > ],
                   CONT.HOOK.XARG #xarg ],
    ARG-ST < #subj &
             [ LOCAL [ CAT [ HEAD noun &
                                  [ CASE #case ],
                             VAL [ SUBJ < >,
                                   SPR < >,
                                   SPEC < >,
                                   COMPS < > ] ],
                       CONT.HOOK.INDEX #xarg ] ],
             #comps &
             [ LOCAL.CAT [ HEAD verb,
                           VAL [ COMPS < >,
                                 SPR < >,
                                 SPEC < >,
                                 SUBJ < [ LOCAL.CAT.HEAD.CASE #case ] > ] ] ] > ].


Once we had all this in place, we were able to pare the "I can eat
glass" sentence:


Source: author
Vetted: f
Judgment: u
Phenomena: {modal}
Ikh ken esn gloz.
Ikh ken es-n gloz.
1SG.NOM can;1SG eat-INF glass. 
I can eat glass.


In addition to this, unlike the other auxiliary verbs we have
implemented so far, ken takes the regular pattern of verbal inflection
in the finite form. To achieve this, ken inherits from the type
regular-verb-lex, which we describe in the next section. 

As a nice bonus, having ken hooked up to the form infelctional
morphology, meant that we got the following sentence parsing, which is
a modal construction acting as a complement to a future tense
construction, which requires that ken be in the nonfinite form:


Source: {a:218}
Vetted: t
Judgment: g
Phenomena: {tam}
Er vet kenen redn yidish.
Er vet ken-en red-n yidish.
3SG.M.HOM will;3SG can-INF speak-INF Yiddish.
He will be able to speak Yiddish.


When generating from the "Ikh ken es-n gloz." One thing we noticed
straight away was that 'ton' was popping up in various places
throughout many of the sentences. This is due to ton also being an
auxiliary verb that combines with nonfinite forms to create the
habitual aspect. The problem is that currently, we are not
constraining the value ASPECT to be more specific for sentences that
are unmarked for aspect. This means that when generating, the trigger
rule for ton is able to apply the constraint 'habitual' as it unifies
with 'aspect'. The solution will probably be to constrain the aspect
for unmarked clauses, however for now we just removed the 'ton'
auxiliary as it currently needs to be hooked up to the inflectional
morphology of regular verbs and so is currently overgenerating anyway
at the moment. After removing the entry we cut the number of sentences
down to 16. Some of these are clearly ungrammatical, with for instance
the infinitive verb coming before the finite verb: "Es-n gloz ken
ikh", and also the finite verb not being in the second position: "Ken
es-n gloz ikh". We'll will return to address this overgeneration at a
later point.
 


DITRANSITIVE VERBS
==================================

In order to get the 'do' part of "It doesn't hurt me" we needed to get
ditransitive verbs working. This is because in Yiddish, this sentence, we thing,
might be less idiomatically translated roughly as "It does me no harm":


Source: author
Vetted: f
Judgment: u
Phenomena: {negation}
Es tut mir nit vey.
Es tut mir nit vey.
3SG.NOM.N do;3SG me NEG woe.
It doesn't hurt me.


In order to implement this, we created types following in the same template 
that the transitive verb types use:


ditransitive-verb-lex := main-verb-lex & ditransitive-lex-item &
  [ SYNSEM.LOCAL.CAT.VAL.COMPS < #comp1, #comp2  >,
    ARG-ST < [ LOCAL.CAT.HEAD noun ],
             #comp1 &
             [ LOCAL.CAT [ VAL [ SPR < >,
                                 COMPS < > ],
                           HEAD noun ] ],
             #comp2 &
             [ LOCAL.CAT [ VAL [ SPR < >,
                                 COMPS < > ],
                           HEAD noun ] ] > ].

nom-dat-acc-ditransitive-verb-lex := ditransitive-verb-lex &
  [ ARG-ST < [ LOCAL.CAT.HEAD noun &
                              [ CASE nom ] ],
             [ LOCAL.CAT.HEAD noun &
                              [ CASE dat ] ],
             [ LOCAL.CAT.HEAD noun &
                              [ CASE acc ] ] > ].


In Yiddish, the default order for objects is dative then accusative,
and our nom-dat-acc-ditransitive-verb-lex thus reflects this ordering.
This will not generalize however, as aside from subcat frames that do
not involve dative objects, there is also the problem of pronouns
altering the order. For instance if the two objects are dative and
accusative, but the accusative object is a pronoun, it will come
first.

We also ran into the problem of 'ton', the verb meaning 'to do', being
an irregular verb. The problem was that all our verbs were being
targeted as candidates for the FORM inflection slot, and thus just
adding 'ton' into this system would mean that it would need to go
through one of the form lex rules, however as an irregular verb this
does not happen. We solved this by abstracting out the constraints
that pertain to whether a verb requires inflectional morphology or not
and thus whether it is a regular or irregular verb. These were then
cross classified with the existing subcat frames, such that verbs are
regular by default and the irregular form of each subcat frame is also
available. The irregular-verb-lex can then also be used as needed for
verbs such as ton, and also all the irregular auxiliaries.


irregular-verb-lex := verb-lex &
  [ INFLECTED.FORM-FLAG + ].

regular-verb-lex := verb-lex &
  [ INFLECTED.FORM-FLAG - ].

intrans-verb-lex-super := nom-intransitive-verb-lex.

trans-verb-lex-super := nom-acc-transitive-verb-lex & 
  [ SYNSEM.LOCAL.CAT.VAL.COMPS < [ OPT-CS type-id ] > ].

strict-trans-verb-lex-super := nom-acc-transitive-verb-lex &
  [ SYNSEM.LOCAL.CAT.VAL.COMPS.FIRST.OPT - ].

ditrans-verb-lex-super := nom-dat-acc-ditransitive-verb-lex.

intrans-verb-lex := intrans-verb-lex-super & regular-verb-lex.
trans-verb-lex := trans-verb-lex-super & regular-verb-lex.
strict-trans-verb-lex := strict-trans-verb-lex-super & regular-verb-lex.
ditrans-verb-lex := ditrans-verb-lex-super & regular-verb-lex.

intrans-irr-verb-lex := intrans-verb-lex-super & irregular-verb-lex.
trans-irr-verb-lex := trans-verb-lex-super & irregular-verb-lex.
strict-irr-trans-verb-lex := strict-trans-verb-lex-super & irregular-verb-lex.
ditrans-irr-verb-lex := ditrans-verb-lex-super & irregular-verb-lex.

1sg-ton-verb-lex :=  ditrans-irr-verb-lex &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PER 1st,
                                                                NUM sg ] ].

2sg-ton-verb-lex := ditrans-irr-verb-lex &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PER 2nd,
                                                                NUM sg ] ].

Once this was set up, we were able to parse our target sentence minus the 
negation marker:


Source: author
Vetted: f
Judgment: u
Phenomena: {word order}
Es tut mir vey.
Es tut mir vey.
3SG.NOM.N do;3SG me woe.
It hurts me.


One catch however, was that we get two parses for this sentence. One
corresponds to the correct SVOO word order, and the other corresponds
to a topicalization of one of the objects: OVOS. This ambiguity arises
because the pronoun form is inherently ambiguous between nominative
and accusative, and there is no determiner on the direct object 'vey'
to indicate accusative case. This raises the question of when SVOO
clauses are topicalized, OVOS is a permitted word order. The reference
grammar seems to imply that it should be OVSO, however is not
clear. Perhaps the best course of action will be to exclude OVOS until
positive evidence is found.

When we generated with "Es tut mir vey." we ran into similar problems
as the last time: that we are not constraining the aspect for unmarked
sentences. This time, the result was that we had the various verbal
prefixes that indicate perfective aspect applying to 'ton'. Once
again, the fix for this will be to constrain the aspect for unmarked
sentences.



NEGATION
========================

As already discussed, sentential negation in Yiddish is realised
through the use of a negative marker 'nit' which in unmarked clauses
occurs just after the finite verb. Currently this is working for
intransitive, transitive and even ditransitive verbs. The latter of
these is illustrated using the "It doesn't hurt me" example modified
to not use a pronoun.


Source: author
Vetted: f
Judgment: g
Phenomena: {negation}
Der man zingt nit.
Der man zing-t nit.
DEF.NOM.M man sing-1SG NEG.
The man isn't singing.

Source: author
Vetted: f
Judgment: g
Phenomena: {negation}
Der man leyent nit dos bukh.
Der man leyen-t nit dos bukh.
DEF.NOM.M man read-1SG NEG DEF.ACC.N book.
The man isn't reading the book.

Source: author
Vetted: f
Judgment: g
Phenomena: {negation}
Es tut nit dos bukh vey.
Es tut nit dos bukh vey.
3SG.NOM.N do;3SG DEF.ACC.N NEG woe.
It doesn't hurt the books.


The problem we are having is that in the "It doesn't hurt me" sentence, we
see pronoun and nit inversion. We have currently not implemented this, however
this is the only remaining hurdle.

While investigation negation, we decided to address the ambiguity
involved in the sentence "Der man zing-t nit.", where we were getting
two parses. Similar to what we've seen before, this was to do with the
basic-head-opt-comp rule which could apply either before or after the
negative rule had applied. We decided to make the negation occur above
the basic-head-opt-comp-rule by adding this constraint:

basic-head-opt-comp-phrase :+
  [ HEAD-DTR.SYNSEM.MODIFIED notmod].

When generating from "Der man zing-t nit.", we got exactly four
sentences. Two of these corresponded to the declarative form of the
sentence, and two to the verb initial interrogative form. The two
parses for each sentence type arise from the fact that nouns are not
marked to agree with possessives, so without any other constraints,
the possessive form of the determiner is generated as well. This is
all nominal, and working correctly!


TEST CORPUS SENTENCE
=========================

We generated a profile from out test corpus skeleton and from this ran
a baseline. The results indicated that none of our test corpus
sentences were parsing. The following sentence is the one we chose to
get parsing this week since it required the implementation of no
phenomena beyond those covered in the previous labs:

		# Forverts 	2009.04.03
		Source: a
		Vetted: f
		Judgment: a
		Phenomena: {}
		di gramatik iz a bazundere tsore.
		di gramatik iz a bazunder-e tsore.
		DEF.NOM.F grammar be;3SG INDF separate-ACC.N trouble.
	
However, the sentence did not parse after we added all the missing
lexical entries. After investigating via the parse chart we discovered
that it required a coupla that connected the subject with the noun
phrase predicate -- work we still had left over from last week. We
added the following rule:

		copula-id-lex := trans-first-arg-raising-lex-item-1 & irregular-verb-lex &
		  [ SYNSEM.LOCAL [ CAT.VAL [ SUBJ < #subj >,
		                             COMPS < #comps > ],
		                   CONT.HOOK.XARG #xarg ],
		    ARG-ST < #subj &
		             [ LOCAL [ CONT.HOOK.INDEX #xarg,
		                       CAT [ VAL [ SPR < >,
		                                   COMPS < > ],
		                             HEAD noun ] ] ],
		             #comps &
		             [ LOCAL.CAT [ VAL [ COMPS < > ],
		                           HEAD noun ] ] > ].
		
Using the rule we created appropriate lex-types mirroring those that
inherit from `copula-verb-lex`:

		1sg-copula-id-lex := copula-id-lex &
		  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PER 1st,
		                                                                NUM sg ] ].

		2sg-copula-id-lex := copula-id-lex &
		  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PER 2nd,
		                                                                NUM sg ] ].

>etc<		

And based on these lex-types, we added the corresponding lexical
entries to our lexicon:

		bin_cop := 1sg-copula-id-lex &
		  [ STEM < "bin" > ].

		bist_cop := 2sg-copula-id-lex &
		  [ STEM < "bist" > ].


>etc<
		
After this, parsing the sentence generated two parse trees as a
product of legitimate ambiguity in Yiddish's singular feminine
pronouns -- which use the same word-form for both the nominative and
accusative case -- and the fact that we were using an indefinite
article as a determiner for the object, which does is not marked for
case. This meant that the sentence could be interpreted as either
`OVS` or `SVO`.



[incr tsdb()] RESULTS
=========================

		Total items:            222
		Positive items:         146
		Negative items:          76
		Parsing positive items:  73
		Parsing negative items:   8
		Coverage:               50%
		Overgeneration:         10%

Compitence Comparison from lab7 baseline to current state:

Prev:  43.8
New    50.0

