LING 567
Lab 6
Chris Curtis and David McHugh (write-up)
05.10.2013

MATRIX YES-NO QUESTIONS

Matrix clause yes-no questions are indicated in Lakota by the word "he" appearing at the end of the sentence. In formal speech, the word "hwo" can be used in place of "he", but only by male speakers.

# 113/G matrix yes/no question
Source: b:151
Vetted: s
Judgment: g
Phenomena: q,tam
yaú kta he?
ya-ú ktA he
ú-2SgAgt ktA he
come-2SG.AGT IRR Q
'will you come?'

# 114/G matrix yes no + neg
Source: b:151
Vetted: s
Judgment: g
Phenomena: q,tam,neg
waŋláke šni he?
waŋ-Ø-l-yáŋkA šni he
waŋyáŋkA-3SgPat-1SgAgt šni he
see-3SG.PAT-1SG.AGT NEG Q
'did you not see him?'

# 115/U matrix yes/no, not sentence-final
Source: author
Vetted: n
Judgment: u
Phenomena: q
yaú he kta?
ya-ú he ktA
ú-2SgAgt he ktA
come-2SG.AGT Q IRR
'will you come?'


In order to model the matrix yes-no questions in Lakota, we created a qpart-lex-item type for the question particles. In addition to constraining the sentential force to "ques" and the first complement to form finite, the qpart-lex-item inherits from the complementizer-lex-item. This type had to be modified to identify its comp list with the only entries on its args list in order to link the semantics correctly.

complementizer-lex-item := raise-sem-lex-item & basic-one-arg &
  [ SYNSEM.LOCAL.CAT [ HEAD comp &
                            [ MOD < > ],
                       VAL [ SPR < >,
                             SUBJ < >,
                             COMPS < #comp > ] ],
    ARG-ST < #comp &
             [ LOCAL.CAT [ MC +,
                           HEAD verb,
                           VAL [ SUBJ < >,
                                 COMPS < > ] ] ] > ].

qpart-lex-item := complementizer-lex-item &
  [ SYNSEM.LOCAL [ CONT.HOOK.INDEX.SF ques,
                   CAT.VAL.COMPS.FIRST.LOCAL.CAT.HEAD.FORM finite ] ].


We added the two question particles to the lexicon.

he := qpart-lex-item &
  [ STEM < "he" > ].

hwo := qpart-lex-item &
  [ STEM < "hwo" > ].


And added trigger for those entries in order for them to contribute to their RELS list and properly link the semantics of the sentence when generating.

he_gr := generator_rule &
  [ CONTEXT.RELS <! [ ARG0.SF ques ] !>,
    FLAGS.TRIGGER "he" ].

hwo_gr := generator_rule &
  [ CONTEXT.RELS <! [ ARG0.SF ques ] !>,
    FLAGS.TRIGGER "hwo" ].

EMBEDDED COMPLEMENT CLAUSES

In Lakota, embedded clauses are marked with a complementizer/relativizer (kiŋ, k'uŋ, or čha). Interrogative clauses use the complementizer "héči", meaning "if" or "whether". The word order between the interrogatives and declaratives is the same. The main verb of the sentence is preceded by the embedded clause.

# 128/G embedded statement
Source: author, after c:71
Vetted: n
Judgment: g
Phenomena: emb-d
šúŋka kiŋ  aǧúyapi kiŋ yúte kiŋ slolwáye
šúŋka kiŋ  aǧúyapi kiŋ yútA kiŋ slol-wa-yÁ
šúŋka kiŋ  aǧúyapi kiŋ yútA kiŋ slolyÁ-1SgAgt
dog DEF bread DEF eat DEF know-1SG.AGT
'I know that the dog ate the bread'

# 133/U čha as complementizer with negative
# this is ungrammatical because čha implies fact
Source: author, after b:813
Vetted: n
Judgment: u
Phenomena: emb-d
wičíŋčala kiŋ oȟ'áŋwašte čha slolwáye šni
wičíŋčala kiŋ oȟ'áŋwašte čha slol-wa-yÁ šni
wičíŋčala kiŋ oȟ'áŋwašte čha slolyÁ-1SgAgt šni
girl DEF be_kind C know-1SG.AGT NEG
'I don't know that the girl is kind'

# 135/U čha as complementizer with verb initial
Source: author
Vetted: u
Judgment: n
Phenomena: emb-d
slolwáye wičíŋčala kiŋ oȟ'áŋwašte čha
slol-wa-yÁ wičíŋčala kiŋ oȟ'áŋwašte čha
slolyÁ-1SgAgt wičíŋčala kiŋ oȟ'áŋwašte čha
know-1SG.AGT girl DEF be_kind C
'I know that the girl is kind'

# 137/G embedded question
Source: b:814
Vetted: s
Judgment: g
Phenomena: emb-q
héčhamuŋ héči imáyuŋǧe
héčhamuŋ héči i-má-Ø-yuŋǧe
héčhuŋ-3SgPat-1SgAgt héči iyúŋǧA-1SgPat-3SgAgt
do_something-3SG.PAT-1SG.AGT whether ask-1SG.PAT-3SG.AGT
'he asked me if I did it'

# 146/U improper use as question particle
Source: author
Vetted: n
Judgment: u
Phenomena: q
yaú kta héči?
ya-ú ktA héči
ú-2SgAgt ktA héči
come-2SG.AGT IRR Q
'will you come?'


In order to model the embedded clauses in our grammar, we again used the complementizer-lex-item type. For the declarative clauses, we created a ppart-lex-item type. This type constrains the index sentential force as prop and also MC - on CAT to prevent this type of complementizer from showing up in matrix clauses.

complementizer-lex-item := raise-sem-lex-item & basic-one-arg &
  [ SYNSEM.LOCAL.CAT [ 
		       HEAD comp &
                            [ MOD < > ],
                       VAL [ SPR < >,
                             SUBJ < >,
                             COMPS < #comp > ] ],
    ARG-ST < #comp &
             [ LOCAL.CAT [ MC +,
                           HEAD verb,
                           VAL [ SUBJ < >,
                                 COMPS < > ] ] ] > ].

ppart-lex-item := complementizer-lex-item &
  [ SYNSEM.LOCAL [ CAT.MC -,
		   CONT.HOOK.INDEX.SF prop ]].

kiŋ_2 := ppart-lex-item &
  [ STEM < "kiŋ" > ].

čha := ppart-lex-item &
  [ STEM < "čha" > ].


For interrogative clauses, we needed to create a new type that inherited from the qpart-lex-item type created above for the matrix questions. This type, embed-qpart-lex-item constrains MC - on CAT also to prevent this type of complementizer from showing up in matrix clauses. Unfortunately we couldn't find any examples of héči used in a sentence that did not use the ditransitive verb "to ask." Since we do not have a ditransitive verb model yet, we have no examples of héči that will parse.

qpart-lex-item := complementizer-lex-item &
  [ SYNSEM.LOCAL [ CONT.HOOK.INDEX.SF ques,
                   CAT.VAL.COMPS.FIRST.LOCAL.CAT.HEAD.FORM finite ] ].

embed-qpart-lex-item := qpart-lex-item &
  [ SYNSEM.LOCAL.CAT.MC - ].

héči := embed-qpart-lex-item &
  [ STEM < "héči" > ].


NON-VERBAL PREDICATES

Lakota uses a series of locative copula verbs (according primarily to gender) in order to to express something being situated in a location. Adjectives, however, exist only as stative verbs and do not exist as non-verbal predicates. Nouns can also be used as verbs. The noun for "man," for example, is also used as the stative verb "to be an adult male." There is also a verb that can be used to classify something as something. This verb is a transitive verb, but is unique in that it does not permit an indefinite determiner on its complement.

# 141/G inanimate postposition
Source: b:146
Vetted: s
Judgment: g
Phenomena: wo,agr
wakšíča kiŋ wáglotapi akáŋl hé
wakšíča kiŋ wáglotapi akáŋl hÁŋ
wakšíča kiŋ wáglotapi akáŋl hÁŋ
bowl    DEF table     on    be_located.INAN
'the bowl is on the table'

# 144/G animate postposition
Source: b:700
Vetted: s
Judgment: g
Phenomena: wo,agr
pahá akáŋl yaŋké
pahá akáŋl yaŋkÁ-3SgAgt
pahá akáŋl yaŋkÁ-3SgAgt
hill on    be_located.ANIM-3SG.AGT
'he is (sits) on  a hill'

# 147/G verbialized noun w/NP subj
# syntactically correct, though nonsense
Source: b:171
Vetted: s
Judgment: g
Phenomena: cop
bébela kiŋ lé hokšíla
bébela kiŋ lé hokšíla
bébela kiŋ lé hokšíla
baby DEF that be_boy
'that baby is a boy'

# 148/G verbialized noun w/affix
Source: b:171
Vetted: s
Judgment: g
Phenomena: cop
homákšila
ho-ma-kšíla
hokšila-1SgPat
be_boy-1SG.PAT
'I am a boy'

# 150/G np-copula verb
Source: author
Vetted: n
Judgment: g
Phenomena: cop
šúŋka kiŋ wičháša héčha
šúŋka kiŋ wičháša héčha
šúŋka kiŋ wičháša héčha
dog DEF man be_a
'The dog is a man.'

# 151/U np-copula verb
Source: author
Vetted: n
Judgment: u
Phenomena: cop
šúŋka kiŋ wičháša waŋ héčha
šúŋka kiŋ wičháša waŋ héčha
šúŋka kiŋ wičháša waŋ héčha
dog DEF man IDF be_a
'The dog is a man.'

In order to model the location predicates, we created a locative-verb-lex for a copula verb type. We also created two subtypes to constrain the appropriate gender of the verb's subject. 

locative-verb-lex := verb-lex & trans-first-arg-raising-lex-item-1 &
  [ SYNSEM.LOCAL [ CAT.VAL [ SUBJ < #subj >,
                             COMPS < #comps >,
                             SPR < >,
                             SPEC < > ],
                   CONT.HOOK.XARG #xarg ],
    ARG-ST < #subj &
             [ LOCAL [ CONT.HOOK.INDEX #xarg,
                       CAT [ VAL [ SPR < >,
                                   COMPS < > ],
                             HEAD noun ] ] ],
             #comps &
             [ LOCAL.CAT [ VAL [ COMPS < > ],
                           HEAD adp ] ] > ].

inanim-loc-verb-lex := locative-verb-lex &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.GEND inanimate ].

anim-loc-verb-lex := locative-verb-lex &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.GEND animate ].

yaŋkÁ_2 := anim-loc-verb-lex &
  [ STEM < "yaŋkÁ" >,
    SYNSEM.LKEYS.KEYREL.PRED "_be+located_v_rel" ].

háŋ := inanim-loc-verb-lex &
  [ STEM < "háŋ" >,
    SYNSEM.LKEYS.KEYREL.PRED "_be+located_v_rel" ].

We did not make any changes this week for adjectives, as they do not exist as non-verbal predicates.

Because there are two different ways for noun phrase predicates, we have two separate models. The first is for noun phrases as stand alone predicates. For this analysis, we created a n-bar-predicate-rule that allows nouns to also exist as verb phrases. We needed to constrain MC - and SPR < > to prevent ambiguity in the parsing. We also constrained ARGS.FIRST to be VAL.SPR < > which forces BARE-NP to operate on the N before n-bar-pred does.

n-bar-predicate-rule := unary-phrase &
  [ SYNSEM.LOCAL.CAT [ MC -,
		       HEAD verb & [ MOD < > ],
		       VAL [ SPR < >,
		 	     COMPS < >,
			     SUBJ < [ LOCAL [ CONT.HOOK.INDEX #arg1,
					      CAT [ HEAD noun,
						  VAL.SPR < > ] ] ] > ] ],
    C-CONT [ HOOK [ LTOP #ltop,
		    INDEX #index,
		    XARG #arg1 ],
	     RELS <! arg12-ev-relation &
		   [ PRED "_be_v_id_rel",
		     LBL #ltop,
		     ARG0 #index,
		     ARG1 #arg1,
		     ARG2 #arg2 ],
		   quant-relation &
		   [ PRED "exist_q_rel",
		     ARG0 #arg2,
		     RSTR #harg ] !>,
	     HCONS <! qeq & [ HARG #harg, LARG #larg ] !> ],
    ARGS < [ SYNSEM.LOCAL [ CAT [ HEAD noun,
				  VAL.SPR < > ],
			    CONT.HOOK [ INDEX #arg2,
					LTOP #larg ]]] > ].


To model the noun phrase copula verb, we created a type tr-np-copula-verb-lex that inherits from the same types as the transitive-verb-lex. The purpose of this type is to precent specifiers form being attached to the noun phrase predicates. We could not inherit directly from that type, as constraining the complement with SPR cons clashed with its parent's constraint.

tr-np-copula-verb-lex := main-verb-lex & transitive-lex-item & cont-pos-rule-dtr & tra-agt-subj-pos-rule-dtr &
  [ SYNSEM.LOCAL.CAT.VAL.COMPS < #comps >,
    ARG-ST < [ LOCAL.CAT.HEAD noun ],
             #comps &
             [ LOCAL.CAT [ VAL [ SPR cons,
                                 COMPS < > ],
                           HEAD noun ] ] > ].

héčha := tr-np-copula-verb-lex &
  [ STEM < "héčha" >,
    SYNSEM.LKEYS.KEYREL.PRED "_be_v_id_rel" ].


OTHER CHANGES

Other changes we made to the grammar included the addition of adpositions so that we could parse the locative copula verb phrases. Lakota uses postpositions, located after the noun phrase. To implement this, we created a postposition type. Unfortunately, we are seeing ambiguous parses on sentences using these structures--the ambiguity is related to the MOD and VAL constraints on postposition-lex and perhaps the locative-verb-lex.

postposition-lex := basic-int-mod-adposition-lex &
  [ SYNSEM.LOCAL.CAT [ HEAD adp,
                       VAL [ SPR < >,
                             SUBJ < >,
                             SPEC < >,
			     COMPS < #comp > ],
		       POSTHEAD + ],
    ARG-ST < #comp &
	     [ LOCAL.CAT [ HEAD noun,
                           VAL.SPR < > ],
                         OPT - ] > ].


We also made a slight bug fix to the tra-obj-1pl-pat-morph-lex-rule, as it did not inherit from tra-obj-pat-lex-rule, which among other things, sets VAL.COMPS.FIRST to OPT +. This was causing some extra ambiguity in our parses.

Our grammar yields 86.4% coverage over the test suite, with 5.9% overgeneration. Using the same testsuite, our lab 5 grammar produced 80.7% coverage and 1.8% overgeneration. We spot checked most of the MRS, and it appeared to 