Lab 7  
Curtis/McHugh  
Lakota [lkt]  
2013.05.17  

# Phenomena

## Modals ('can')

Modals in Lakota are uncommon and occur in a different distribution than
most other verbs, even clausals. In particular, they exhibit agreement
between the subject of the modal verb and that of the complement
clause. For example:

(152)  
Source: author  
Vetted: n  
Judgment: g  
Phenomena: m,agr  
žaŋžáŋla wáta owákihi  
žaŋžáŋla wa-yútA o-wa-kíhi  
žaŋžáŋla yútA-1SgAgt okíhi-1SgAgt  
glass eat-1SG.AGT be_able-1SG.AGT  
'I can eat glass'  

They otherwise interact normally as verbal heads, including with the
enclitics:

(155)  
Source: b:427  
Vetted: s  
Judgment: g  
Phenomena: m,agr,q  
yáu oyákihi he?  
ya-ú o-ya-kíhi he  
ú-2SgAgt okíhi-2SgAgt he  
come_here-2SG.AGT be_able-2SG.AGT Q  
'Can you come here?'  

To implement the modals we created a new lexical type, modal-subj-raise-aux-with-pred:

  subj-raise-aux-with-pred := subj-raise-aux & norm-sem-lex-item & trans-first-arg-raising-lex-item-1.

  modal-subj-raise-aux-with-pred := subj-raise-aux-with-pred & tra-agt-subj-pos-rule-dtr &  
    [ ARG-ST < [ ],  
               [ LOCAL.CAT [HEAD verb &  
                           [ AUX - ] ] ] > ].  

By inheriting from subj-raise-aux-with-pred, the modals exhibit the
proper behavior of raising the subject and adding the predicate. This
co-identification of subject enforces the agreement constraint; we
needed to also make the modals inherit from tra-agt-subj-pos-rule-dtr in
order to allow them to take a pronomial subject affix. We also
constrained them to only allow [ AUX - ] complements to enforce the
restrictions on the other AUX verbs (primarily enclitics) applying at
the sentence level.

Our current grammar parses test item #152 ('I can eat glass'; see above)
and produces the correct semantics:

h1 e2{ prop-or-ques tense aspect mood semsort }  
{ h3:_glass_n_rel<>(x4{ semsort bool cog-st 3rd number inanimate })  
  h5:exist_q_rel<>(x4,h6.h7)  
  h8:_eat_v_rel<>(e9{ tense aspect mood iforce semsort }, x10{ semsort in-foc + 1st sg gender }, x4)  
  h11:_can_v_rel<>(e2,h12) }   
{ h6 =q h3 h12 =q h8 }  

This example also successfully generates.

## Negation

Negation in Lakota occurs at the sentence level, expressed by a postverbal enclitic:

(67)  
Source: author  
Vetted: f  
Judgment: g  
Phenomena: neg  
igmú kiŋ sápa šni  
igmú kiŋ sápA šni  
igmú kiŋ sápA šni  
cat DEF be_black NEG  
'The cat is not black.'  

We had previously implemented negation like the other postverbal enclitics, as an aux verb:

   neg-aux-lex := subj-raise-aux-with-pred &  
     [ SYNSEM.LOCAL.CAT [ HEAD.FORM negative-form,  
                          VAL.COMPS.FIRST.LOCAL.CAT.HEAD.FORM nonfinite+irrealis-form ] ].  

This appears to be working properly, and required no changes to this
week's grammar. We successfully parse test item # 156 ('It doesn't hurt
me') and produce the correct semantics:

(156)  
Source: author  
Vetted: n  
Judgment: g  
Phenomena: neg  
oyázaŋmaye šni.  
oyázaŋ-ma-Ø-yA šni  
oyázaŋyA-1SgPat-3SgAgt šni  
injure-1SG.PAT-3SG.AGT NEG  
'It doesn't hurt me'  

h1 e2{ prop-or-ques tense aspect mood semsort }  
{ h3:_hurt_v_rel<>(e4{ tense aspect mood iforce semsort }, x5{ semsort in-foc + 3rd sg gender},  
  x6{ activ-or-more + semsort sg 1st gender })  
  h7:neg_rel<>(e2,h8) }  
{ h8 =q h3 }  

This example successfully generates.

# Other things we fixed

## Pronouns (and corpus sentence)

In order to parse a sentence from our corpus, we needed to handle the use of 'lé' (this) functioning as a pronoun instead of as a demonstrative. For example:

(157)  
Source: d  
Vetted: s  
Judgment: g  
Phenomena: pn  
lé ȟeíle héčha.  
lé ȟeíle héčha  
lé ȟeíle héčha  
that volcano be_of_such  
'It's a volcano.'  

To implement this, we created a new lexical type, pron-lex. To
distinguish pronouns from regular nouns, we abstracted the common
constraints into a new noun-super-lex:

  noun-super-lex := basic-noun-lex & basic-one-arg & no-hcons-lex-item & non-mod-lex-item &  
    [ SYNSEM.LOCAL.CAT.VAL [ COMPS < >,  
                             SUBJ < >,  
                             SPEC < > ] ].  

and split off the [ VAL.SPR < [ HEAD det ] > ] (nouns) and [ VAL.SPR < > ]
(pronouns) constraints into two separate subtypes:

  noun-lex := noun-super-lex &  
    [ SYNSEM.LOCAL.CAT.VAL [ SPR < #spr &  
                                   [ LOCAL.CAT.HEAD det ] > ],  
      ARG-ST < #spr > ].  

  pron-lex := noun-super-lex &  
    [ SYNSEM.LOCAL.CONT [ RELS <! [ PRED "pronoun_n_rel" ] !>,  
                          HOOK.INDEX.PNG.PER 3rd ] ].  

We then created additional lexical entries inheriting pron-lex for the
determiners that can also act as pronouns.

This example successfully generates.

Unfortunately, the addition of a pronoun form for lé does result in
several spurious parses. This is in part due to the fact that we now
have three different lexical entries, as well as not having the proper
VAL and MOD constraints on the pronoun lex type. We may also need to
implement a PRONOUN feature to bar it from being processed by the
n-bar-predicate-rule.

## Ditransitives

One of the issues we found in Lab 6 was being able to parse
interrogative clauses without a complementizer. In Lakota these are
expressed as ditransitive verbs taking a clausal second complement:

(137)  
Source: b:814  
Vetted: s  
Judgment: g  
Phenomena: emb-q  
héčhamuŋ héči imáyuŋǧe  
héčhamuŋ héči i-má-Ø-yuŋǧe  
héčhuŋ-3SgPat-1SgAgt héči iyúŋǧA-1SgPat-3SgAgt  
do_something-3SG.PAT-1SG.AGT whether ask-1SG.PAT-3SG.AGT  
'he asked me if I did it'  

To implement these verbs, we needed to develop a
clausal-ditrans-verb-lex. We first abstracted the argument optionality
up from tr-active-verb-lex to active-verb-lex:

  active-verb-lex := tra-pat-obj-dtr &  
    [ INFLECTED [ TRA-PAT-OBJ-POS-FLAG -,  
                  TRA-AGT-SUBJ-POS-FLAG - ] ].  

  tr-active-verb-lex := transitive-verb-lex & active-verb-lex.  

We then abstracted clausal and clausal-transitive superclasses:

  clausal-verb-lex := main-verb-lex & tra-agt-subj-pos-rule-dtr &  
    [ SYNSEM.LOCAL [ CONT.HOOK.INDEX.SF prop-or-ques ] ].  

  clausal-trans-verb-lex := clausal-verb-lex & clausal-second-arg-trans-lex-item &  
    [ SYNSEM.LOCAL.CAT.VAL.COMPS [ FIRST #comp &  
                                         [ LOCAL.CAT.HEAD comp ],  
                                   REST <>],  
      ARG-ST < [ ], #comp >].  

And created a clausal-ditrans-verb-lex tying everything together:

  clausal-ditrans-verb-lex := clausal-verb-lex & clausal-third-arg-ditrans-lex-item & active-verb-lex &  
    [ SYNSEM.LOCAL.CAT.VAL [ COMPS < #comp1, #comp2 >,  
                             SUBJ < #subj > ],  
      ARG-ST < #subj,  
              #comp1 &  
              [ LOCAL.CAT.HEAD noun ],  
              #comp2 &  
              [ LOCAL.CAT.HEAD comp ] > ].  

Inheriting from clausal-third-arg-ditrans-lex-item constrains the second
complement to be INDEX event instead of ref-ind.

This example successfully generates.

## Postpositions

Another issue we found in Lab 6 was that our MRS for our postposition
example was incorrect:

(141)  
Source: b:146  
Vetted: s  
Judgment: g  
Phenomena: wo,agr  
wakšíča kiŋ wáglotapi akáŋl hé  
wakšíča kiŋ wáglotapi akáŋl hÁŋ  
wakšíča kiŋ wáglotapi akáŋl hÁŋ  
bowl    DEF table     on    be_located.INAN  
'the bowl is on the table'  

   EB> The MRS isn't quite right for this one.  In particular:  
   1) The ARG1 of _on-top_p_rel doesn't point to anything  
   2) The LBL of _on-top_p_rel is the LARG of a phantom qeq  

To fix the phantom qeq we needed to first change locative-verb-lex to inherit from
trans-first-arg-raising-lex-item-2, and not
trans-first-arg-raising-lex-item-1:

  locative-verb-lex := verb-lex & trans-first-arg-raising-lex-item-2 & tra-agt-subj-pos-rule-dtr &  
    [ SYNSEM.LOCAL [ CAT.VAL [ SUBJ < #subj >,  
                               COMPS < #comps >,  
                               SPR < >,  
                               SPEC < > ],  
                     CONT.HOOK.XARG #xarg ],  
      ARG-ST < #subj &  
               [ LOCAL [ CONT.HOOK.INDEX #xarg,  
                         CAT [ VAL [ SPR < >,  
                                     COMPS < > ],  
                               HEAD noun ] ] ],  
               #comps &  
               [ LOCAL.CAT [ VAL [ COMPS < > ],  
                             HEAD adp ] ] > ].  

Then to fix the ARG1 to point to the noun on its mod list, we needed to update our lexical type for postpositions:

  postposition-lex := basic-int-mod-adposition-lex &  
    [ SYNSEM.LOCAL [ CAT [ HEAD adp &  
                                [ MOD < [ LOCAL [ CAT.HEAD noun,  
                                                  CONT.HOOK.INDEX #arg ] ] > ],  
                           VAL [ SPR < >,  
                                 SUBJ < >,  
                                 SPEC < >,  
                                 COMPS < #comp > ],  
                           POSTHEAD + ],  
                     CONT.HOOK.XARG #arg ],  
      ARG-ST < #comp &  
               [ LOCAL.CAT [ HEAD noun,  
                             VAL.SPR < > ],  
                 OPT - ] > ].  

The postpositions now produce the correct semantics. We get two
ambiguous parses with identical semantics; the ambiguity, however is
purely structural and the only differential is whether the no-drop
subject rule is applied to the verb or not. (It makes no difference,
since in either case the SUBJ is satistfied by the final SUBJ-HEAD
rule.)

This example surprisingly no longer successfully generates. We were thus
far unable to determine what is preventing it from generating, though we
suspect it has something to do with the verb itself being semantically
empty. This is something we plan to dig into further for next week.


## NP Copula Verbs

The final issue from Lab 6 that we addressed this week was the missing
quantifier on NP copula verbs:

(150)  
Source: author  
Vetted: n  
Judgment: g  
Phenomena: cop,agr  
hokšíla kiŋ wičháša héčha  
hokšíla kiŋ wičháša héčha  
hokšíla kiŋ wičháša héčha  
boy DEF man be_a  
'The boy is a man.'  

  EB> This one, meanwhile, is short a quantifier.  Can you make
  the copula require an NP complement (i.e., SPR < >)?  That should
  force the N through the  bare NP rule (assuming you have that?).

  EB> So overt determiners are ungrammatical there?  In that case,
  if you really want to select an N' complement, you have to have
  the verb supplying the quantifier.  Alternatively, you could try
  constraining the COG-ST of the N' predicate so that no (demonstrative)
  determiners could possibly have attached, letting only the bare-np
  rule work.

To fix this we decided to have the verb supply the missing quantifier:

  tr-np-copula-verb-lex := alt-main-verb-lex & transitive-lex-item & cont-pos-rule-dtr & tra-agt-subj-pos-rule-dtr &  
  [ SYNSEM.LOCAL [ CAT [ HEAD verb,  
		         VAL [ COMPS < #comps >,  
			       SUBJ < [ LOCAL [ CONT.HOOK.INDEX #arg1 ] ] > ] ],  
    		   CONT [ HOOK [ LTOP #ltop,  
		    		 INDEX #index,  
		    		 XARG #arg1 ],  
         		  RELS <! arg12-ev-relation &  
		   		  [ PRED "_be_v_id_rel",  
		     		    LBL #ltop,  
		     		    ARG0 #index,  
		     		    ARG1 #arg1,  
		     		    ARG2 #arg2 ],  
		   		  quant-relation &  
		   		  [ PRED "exist_q_rel",  
		     		    ARG0 #arg2 ] !> ] ],  
     ARG-ST < [ LOCAL [ CAT [ HEAD noun ]]],  
                #comps &  
                [ LOCAL.CAT [ VAL [ SPR cons,  
                                    COMPS < > ],  
                              HEAD noun ] ] > ].   

In order to allow two items on the RELS list, we had to create alternate
supertypes to inherit from; whereas norm-sem-lex-item inherits from
single-rel-lex-item, alt-norm-sem-lex-item does not:

  alt-norm-sem-lex-item := norm-hook-lex-item & icons-lex-item.

  alt-basic-verb-lex := alt-norm-sem-lex-item &   
    [ SYNSEM [ LOCAL [ CAT.HEAD verb,  
  		       CONT.HOOK [ INDEX #index,  
				   ICONS-KEY.CLAUSE #index,  
				   CLAUSE-KEY #index ] ],  
	       LKEYS.KEYREL event-relation ] ].  

  alt-main-verb-lex := verb-lex & alt-basic-verb-lex &  
    [ SYNSEM.LOCAL [ CAT [ HEAD.AUX -,  
                           VAL [ SPR < >,  
                                 SPEC < >,  
                                 SUBJ < #subj > ] ],  
                     CONT.HOOK.XARG #xarg ],  
      ARG-ST.FIRST #subj &  
                   [ LOCAL [ CAT.VAL [ SPR < >,  
                                       COMPS < > ],  
                             CONT.HOOK.INDEX #xarg ] ] ].  


This example also successfully generates.

# Current Coverage/Comparison to baseline

On our current grammar and testsuite, we are achieving 88.5% coverage,
with 4.8% overgeneration. This compares favorably the Lab 6 grammar's
performance on this testsuite with the Lab 6 grammar of 82.3% coverage;
the Lab 6 grammar also produced 4.8% overgeneration, so we have not
introduced any new parses for negative examples.

 
