Jason Shaw (author, topicofocaphile, non-configurational student)
Prescott Klassen (generator extraordinaire, world-renowned tsdb tamer)
2/26/10
Lab 8

###############################################################################
CONTENTS
###############################################################################

1. Description of topic and focus in Nishnaabemwin
2. Implementation of topic and focus
3. Deficiencies in the implementation
4. Efforts toward generation
5. Changes in semi.vpm and accompanying effects on generation
6. Current coverage of the grammar

A. Appendix A: Generation report
B. Appendix B: Justification of present analysis of information structure

###############################################################################
1. DESCRIPTION OF TOPIC AND FOCUS IN NISHNAABEMWIN
###############################################################################

Information structure is a relatively understudied area of Algonquian linguistics.  Consequently, not much is known (or remarked upon, at least) regarding the use of prosody to mark information structure in Nishnaabemwin or closely related languagues.  However, there are indications that this is accomplished effectively through syntactic means.

Unmarked word order in Nishnaabemwin is VOS (or perhaps more properly, verb-obviative-proximate).  If a verbal argument appears before the verb, then it is marked for information structure.  When both arguments of a transitive verb appear preverbally, the first is marked for topic and the second for focus.  (Themes of ditransitive verbs can also be given information structure, but we do not handle ditransitives in our grammar.):

	Gaag zhiishiiban wmnipawaawaan
	Gaag zhiishiib-an w-doo-mnopwaad-aa-an
	porcupine duck-obv 3-PRES-like+the+taste+of-DIR.THM-GL.3SG
	'Speaking of the porcupine, it's the duck(s) that it likes to eat'

When only one argument is preverbal, its topicality/focality is ambiguous:

	# Ambiguous between topic or focus for "Nenbozh"
	Nenbozh wiizegzi
	Nenbozh w-wii-zegzid-0
	Nenabush 3-FUT-be+frightened-3
	'It is Nenabush who will be frightened/Speaking of Nenabush, he will be frightened'

However, obviative nouns cannot be topics, so preverbal obviatives are unambiguously focal:

	# Not ambiguous; "Nenbozh" can only be focused
	Nenbozhoon wiizegziwan
	Nenbozh-oon w-wii-zegzid-wan
	Nenabush-OBV 3-FUT-be+frightened-3.OBV
	'It is Nenabush who will be frightened'

This also enables us to create ungrammaticalities with information structure -- since obviatives cannot be topics, it follows that a sentence in the form Obv-Prox-Verb will be ungrammatical:

	# Ungrammatical
	Gaagwan zhiishiibag wmnipawigowaan
	Gaag-wan zhiishiib-ag w-doo-mnopwaad-igw-waa-an
	porcupine-obv duck-PL 3-PRES-like+the+taste+of-INV.THM-GL.3PL-AC.OBV
	'Speaking of the porcupine(s), it's the ducks that it(they) like(s) to eat'

There are other methods for marking information structure in Nishnaabemwin, but we have not addressed them in this lab.  A description of them is in section 3, "Deficiencies in the implementation".  The above analysis of information structure was a synthesis of information on several Algonquian languages, as Nishnaabemwin needs further work in this area.  As a result, the analysis of information structure may not be fully appropriate.  An outline of the reasoning that led to the above analysis is given in the appendix.

###############################################################################
2. IMPLEMENTATION OF TOPIC AND FOCUS
###############################################################################

The first step to adding information structure to our grammar was to create a feature INFO-STR which would be a feature of semantic indices.  The supertype of our index types is individual, so we add it there:

	individual :+ [ INFO-STR info-str ].

Next we need a hierarchy to denote whether a particular referent is marked for information structure, and if so, what kind:

	info-str := *top*.
	marked := info-str.
	unmarked := info-str.
	focus := marked.
	topic := marked.

With this in place, we can begin implementing information structural phenomena which are specific to Nishnaabemwin.  Immediately we can encode the information structure of polar questions.  The question clitic "na" indicates that the preceding word is what is being questioned -- that is, what is in focus.  So we add the following constraint to question-clitic-lex:

	question-clitic-lex :+ [ SYNSEM.LOCAL.CAT.HEAD.MOD.FIRST.LOCAL.CONT.HOOK.INDEX.INFO-STR focus ].

Now we tackle the information structure of declarative sentences.  First we establish features TOPIC and FOCUS (on SYNSEM.LOCAL.CAT) to keep track of whether a grammar rule has applied which has provided topic or focus:

	cat :+
	  [ TOPIC bool,
	    FOCUS bool ].

We also define two subtypes of headed-phrase which enforce identity between the mother and head daughter's TOPIC or FOCUS values:

	same-topic-as-head := headed-phrase &
	  [ SYNSEM.LOCAL.CAT.TOPIC #topic,
	    HEAD-DTR.SYNSEM.LOCAL.CAT.TOPIC #topic ].

	same-focus-as-head := headed-phrase &
	  [ SYNSEM.LOCAL.CAT.FOCUS #focus,
	    HEAD-DTR.SYNSEM.LOCAL.CAT.FOCUS #focus ].

These constraints are placed on head-initial and our clause-finishing rules int-cl and decl-cl, so that information about the application of TOPIC and FOCUS are passed all the way up the tree:

	head-initial :+ same-topic-as-head & same-focus-as-head.
	decl-cl :+ same-topic-as-head & same-focus-as-head.
	int-cl :+ same-topic-as-head & same-focus-as-head.

Now we modify all of our head-final rules (subj-head, comp-head, and comp-head-2).  These are the rules which are used to place verbal arguments before the verb.  It is clear now that whenever these rules fire, they are marking information structure.  Any of them can be used to mark either topic or focus.  We will create new rule types topic-head and focus-head:

	topic-head := head-final & same-focus-as-head
	  [ SYNSEM.LOCAL.CAT.TOPIC +,
	    HEAD-DTR.SYNSEM.LOCAL.CAT.TOPIC -,
	    NON-HEAD-DTR.SYNSEM [ LOCAL.CONT.HOOK.INDEX [INFO-STR topic,
							 PNG.OBVIATION prox ] ] ].

	focus-head := head-final & same-topic-as-head
	  [ SYNSEM.LOCAL.CAT.FOCUS + ,
	    HEAD-DTR.SYNSEM.LOCAL.CAT [ TOPIC -,
					FOCUS - ],
	    NON-HEAD-DTR.SYNSEM.LOCAL.CONT.HOOK.INDEX.INFO-STR focus ].

Type topic-head copies up the FOCUS value while modifying TOPIC, and focus-head does the opposite.  Additionally, focus-head constrains its head daughter to be [ TOPIC - ] because we only want topical expressions to appear to the left of focal expressions, and focal-head give focus to its non-head (left) daughter.  Thus, its head (right) daughter cannot have been given topicality.  By modifying the values of TOPIC and FOCUS, topic-head and focus-head record their presence in the parse and avoid spinning.  Next we cross-classify these types with the head-final phrases:

	topic-subj-head-phrase := subj-head-phrase & topic-head.
	topic-comp-head-phrase := comp-head-phrase & topic-head.
	topic-comp-head-phrase-2 := comp-head-phrase-2 & topic-head.
	focus-subj-head-phrase := subj-head-phrase & focus-head.
	focus-comp-head-phrase := comp-head-phrase & focus-head.
	focus-comp-head-phrase-2 := comp-head-phrase-2 & focus-head.

And these now give us six head-final rules where before there were three:

	topic-comp-head := topic-comp-head-phrase.
	focus-comp-head := focus-comp-head-phrase.
	topic-subj-head := topic-subj-head-phrase.
	focus-subj-head := focus-subj-head-phrase.
	topic-comp-head-2 := comp-head-phrase-2.
	focus-comp-head-2 := focus-comp-head-phrase-2.

The above six rules replace comp-head, subj-head, and comp-head-2.

Now whenever a head-final phrase structure rule is required to parse a sentence, it will add the appropriate information structure.  Finally, topic-head required a couple of additional constraints.  First, obviative noun phrases cannot appear as topics, but they can be focused.  It is not appropriate to mark information structure with the application of an obviation lexical rule, because obviative nouns may appear behind the verb with unmarked information structure.  So to ensure that the only INFO-STR value attained by obviative nouns is focus, we constrain the non-head daughter of topic-head to be proximate.  A proximate noun is not necessarily topical, but an obviative one can never be.

The interaction of topic-head, focus-head, and polar questions works out very nicely: because the question clitic is enforcing [ INFO-STR focus ] on the head it modifies, only focus-head can combine the focus-clitic constituent with the rest of the sentence.  This prevents, for example, placing two verbal arguments before the verb while questioning the first one.  "Gaag-wan na zhiishiib w-doo-mnopwaad-aa-an" parsed in previous iterations of this grammar, but is now considered ungrammatical because "gaag-wan" is focused, forcing "gaag-wan na" to be attached to the rest of the sentence by focus-head.  Since "zhiishiib w-doo-mnopwaad-aa-an" can only be built with topic-head or focus-head, neither of which are valid head-daughters for focus-head, the sentence does not parse.*

*The sentence does, of course, parse with our grammar, but only by coordinating "gaag-wan na" and "zhiishiib" so that "gaag-wan na zhiishiib" is a single verbal argument.  The desired interpretation in which "gaag-wan" and "zhiishiib" are distinct arguments of the verb is not possible.

###############################################################################
3. DEFICIENCIES IN THE IMPLEMENTATION
###############################################################################

The primary difficulty remaining to be solved in the implementation of information structure in Nishnaabemwin is what has been referred to as "splattered" noun phrases.  It is possible to focus only pieces of a noun phrase, leaving the rest of it behind the verb:

	Nswi giibizhaamgadoon jiimaanan
	Nswi gii-bizhaamgak-oon jiimaan-an
	three PAST-come-3PL boat.IN-3PL
	"Three canoes came"

The number word "nswi" appears in focus position, while the noun it modifies, "jiimaanan" follows the verb.  A proper analysis of this would link the quantifier and the noun semantically and additionally provide [ INFO-STR focus ] to "nswi".  Even disregarding cases like this, questioning of multi-word noun phrases shares a similar problem, because the question clitic "na" must be the second word in the sentence, even if what is focused is the entire noun phrase:

	Maaba na nishnaabe moonshkwed?
	Maaba na nishnaabe w-doo-moonhashkiwed-0
	this.3SG.AN QUES Indian.AN.3SG 3-PRES-weed-SG
	'Is it this Indian who is weeding?'

Presumably the focus can lie on just the determiner or the entire noun phrase, although whether this is the case is unknown.

Finally, Nishnaabemwin does have other mechanisms for marking focus, most notably cleft-like constructions using the discourse particle "mii".  These constructions, however, make use of relative clauses, so we have ignored them.  Nishnaabemwin also makes use of left-dislocation to mark topics, which is distinct from the sentence-initial topic position implemented here.  However, this is a useless distinction except in the presence of the sentence-initial negative adverb, and we do not have this adverb implemented yet.  When we add an analysis of this adverb, we will also provide a mechanism for left-dislocation.

###############################################################################
4. EFFORTS TOWARD GENERATION
###############################################################################

Before adding variable-property mapping rules to the grammar, we wanted to ensure we were able to generate in order to isolate .vpm details from our grammar itself. We were unable to get generation going for Lab 7, so knew that there were probably lexical rules that were causing generation to "spin" or causing cycles. By reducing the number of maximum edges to 100 and reviewing the generation charts, we found that our head-comp and comp-head rules were feeding each other, causing "spin". We added the following constraints which stopped the "spin":

	head-comp-phrase := basic-head-1st-comp-phrase & head-initial-head-nexus &
	  [ SYNSEM.LOCAL.CAT.HEAD +nvjrpdmo ].

	comp-head-phrase := basic-head-1st-comp-phrase & head-final-head-nexus &
	  [ SYNSEM.LOCAL.CAT.HEAD +nvjrpdmo ].

After these changes, we were no longer spinning and were finally getting proper error messages from the LKB. We discovered that the individual verb class inflection pipelines we introduced in Lab 7 had suffered from copy and paste errors, two daughter rules were re-applied in the person prefix and suffix rules causing a cycles in generation. By removing these rules from pipeline, we began to get realizations.  At this point, we turned toward implementing variable-property mapping.

After adding the vpm rules and our information structure types and rules to the grammar, we continued to tweak the grammar for generation. We added several constraints to reduce generation:

1) to isolate independent and conjunct inflections in generation, we added MC+ and MC- constraints directly on person prefix and suffix rules:

	ind-cat-rule := word-or-lexrule.

	ind-cat-mc-rule := ind-cat-rule &
	  [ SYNSEM.LOCAL.CAT [ HEAD +vc,
		               MC + ] ].

	conj-cat-rule := word-or-lexrule.

	conj-cat-mc-rule := conj-cat-rule &
	  [ SYNSEM.LOCAL.CAT [ HEAD +vc,
		               MC - ] ].

Adding these constraints successfully constrained conjunct and independent order generation in VAI, VII, VTI, and VTA inflections. Remaining are VTA-C, VTI-C, and copula-verb types to fine-tune next week.

2) In order to constrain the inflection of copula selected nouns for all of our noun objects in our transitive verbs we experimented with VTI verbs and added the following constraint to the VTI supertype:

	verb-class-VTI-verb-lex := vti-tense-rule-dtr & vti-negation-rule-dtr & vti-aspect-rule-dtr & vti-theme-rule-dtr & transitive-verb-lex &
	  [ INFLECTED -,
	    SYNSEM.LOCAL.CAT.VAL.COMPS.FIRST.LOCAL [ CAT.HEAD.LOC -,
		                                     CONT.HOOK.INDEX.PNG.GEND inan ] ].

The [ LOC - ] constraint blocks the generation of copula-inflected nouns in VTI generated inflection.

3) We removed extraneous inflection rules from our verb classes. These inflections were created early in the project and were intended to provide morpheme slots for morphophonologically differentiated versions of SG and PL for some verbs. We decided to select a canonical morpheme for the verb class rather than deal with the ambiguity of multiple morphemes or creating many more individual verb classes. An example of this reduction of morphemes from the VAI class:

	;;; Removed and canonized across all VAI PL -min

	;vai-PL-Prox-morph-2-lex-rule := vai-person-suffix-lex-rule & ind-cat-mc-rule &
	;  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
	;                                                                GEND anim,
	;                                                                OBVIATION prox ] ].

	;vai-PL-Prox-morph-3-lex-rule := vai-person-suffix-lex-rule & ind-cat-mc-rule &
	;  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
	;                                                                GEND anim,
	;                                                                OBVIATION prox ] ].

	;vai-PL-Prox-morph-4-lex-rule := vai-person-suffix-lex-rule & ind-cat-mc-rule &
	;  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
	;                                                                GEND anim,
	;                                                                OBVIATION prox ] ].

	;vai-PL-Prox-morph-5-lex-rule := vai-person-suffix-lex-rule & ind-cat-mc-rule &
	;  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
	;                                                                GEND anim,
	;                                                                OBVIATION prox ] ].

	;vai-PL-Prox-morph-6-lex-rule := vai-person-suffix-lex-rule & ind-cat-mc-rule &
	;  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
	;                                                                GEND anim,
	;                                                                OBVIATION prox ] ].

All of the above changes dramatically reduced the number of our realizations.

###############################################################################
5. CHANGES IN semi.vpm AND ACCOMPANYING EFFECTS ON GENERATION
###############################################################################

Once generation was functioning in our grammar, we implemented the following vpm rules:

	PNG.PERNUM : PER NUM
	  1SG <> first sg
	  1PL <> first pl
	  1st <> first !
	  1st << first *
	  2SG <> second sg
	  2PL <> second pl
	  2nd <> second !
	  2nd << second *
	  3SG <> third sg
	  3PL <> third pl
	  3rd <> third !
	  3rd << third *
	  *  >> ! !
	  !  << * *

	E.TENSE : TENSE
	  past     <> past
	  present  <> pres
	  future   <> fut
	  present << *

	E.ASPECT : ASPECT
	  habituality >> habituality
	  habituality << habituality
	  begin >> begin
	  begin << begin
	  end >> end
	  end << end
	  * >> no-aspect
	  no-aspect << no-aspect

	PNG.GEND : GENDER
	  anim >> anim
	  anim << anim
	  inan >> inan
	  inan << inan
	 
	PNG.OBVIATION : OBVIATION
	  prox >> prox
	  prox << prox
	  obv >> obv
	  obv << obv

	SF : SF
	  prop <> prop
	  ques <> ques
	  prop-or-ques >> prop-or-ques
	  prop << prop-or-ques
	  comm <> comm

	INFO-STR : INFO-STR
	  topic <> topic
	  focus <> focus
	  unmarked << info-str
	  info-str >> unmarked

	COG-ST : COG-ST
	  ; Non-disunctive types
	  type-id <> type-id
	  uniq-id <> uniq-id
	  familiar <> familiar
	  activated <> activated
	  in-foc <> in-foc

	  ; Disjunctions of two
	  activ+fam <> activ+fam
	  uniq+fam <> uniq+fam
	  activ-or-more <> activ-or-more
	  uniq-or-less <> uniq-or-less

	  ; Disjunctions of three
	  uniq+fam+act <> uniq+fam+act
	  fam-or-more <> fam-or-more
	  fam-or-less <> fam-or-less

	  ; Disjunctions of four
	  uniq-or-more <> uniq-or-more
	  activ-or-less <> activ-or-less

We had an immediate reduction of realizations and for short sentences (one noun, one verb) we did not have to increase maximum-number-of-edges beyond the default.  We then returned to our grammar to make further adjustments to reduce ambiguity in generation.

###############################################################################
6. CURRENT COVERAGE OF THE GRAMMAR
###############################################################################

Total items: 358
Positive items: 241
Negative items: 117

Lab 7 baseline:
Coverage: 90.0%
Distinct analyses (+): 2.24
Overgeneration: 13.7%
Distinct analyses (-): 3.12
Total analyses: 2.30

Lab 8 coverage:
Coverage: 85.9%
Distinct analyses (+): 2.70
Overgeneration: 12.8%
Distinct analyses (-): 3.53
Total analyses: 2.76

###############################################################################
A. APPENDIX A: GENERATION REPORT
###############################################################################

We wanted to ensure we were generating for our basic 4 verb classes VAI, VII, VTA and VTI. Starting with a simple VII:

	Waagaakwad wiigiinboode
	Waagaakwad w-wii-giinboodeg-0
	axe.IN.3SG 3-FUT-be+sharpened-3SG
	'The axe needs sharpening'

Results: 4 realizations, all sharing the same MRS. Given that Nishnaabemwin is free word order we would expect 2 realizations, but we are now getting a focus-subj-head pair and head-subj based on the ambiguity introduced by our information structure grammar rules.

Next, a VAI verb:

	Nimoog doonbaamin
	Nim-oog w-doo-nbaad-min
	dog.AN.3PL 3PL-PRES-sleep-3PL
	"Dogs sleep."

Results: 4 realizations, with a focus-subj-head pair and a head-subj pair.

VTI verb (NB. this sentence may required increasing maximum edges):

	Nmamaag giizhitoonaawaan jiimaanan
	Nmamaa-g w-gii-zhitood-oo-naawaan jiimaan-an
	my+mother.AN-3PL 3-PAST-make-THM2.VTI-GL.PL boat.IN-3PL
	'My mothers made the boats'

Results: 49 realizations. With 3 words and information structure we might expect 6 realizations, but our theme suffixes for VTI are verb-specific, adding no semantic content. We will need to explore how to constrain this next week. The semantic-less themes cause a combinatorial explosion of realizations.

VTA verb (NB. this sentence may required increasing maximum edges):

	Nimoog giibminaashkwaawaawaan daabaanan
	Nim-oog w-gii-bminaashkwaad-aa-waa-an daabaan-an
	dog.AN.3PL AC.3PL-PAST-visit-DIR.THM-AC.3PL-GL.3.OBV car.3.OBV
	"The dogs chase cars."

Results: 51 realizations. We have not constrained VTA to select only [ LOC - ] objects (due to the complexity of direct-inverse). We will be cleaning this up next week. It does show, however, that our object noun is being inflected for copula verb selection.

Based on our vpm aspect entries we are able to deal with our aspect-inflected verbs properly:

	Nnahaangnikwem doontaagshkigwaase
	Nnahaangnikwem w-doo-ntaa-gshkigwaasod-0
	my+daughter+in+law.AN.3SG 3-PRES-HAB.be+good+at-sew-3SG
	'My daughter-in-law sews well'
 
Results: 4 realizations, one pair with the aspect and one without. This might be the best sentence in the suite!

We also have good generation for our unexpressed arguments:

	Wiigsinaa
	W-wii-gsinaag-0
	3-FUT-be+cold-3SG
	"It will be cold"

Results: 2 realizations

We are still exceeding the maximum number of edges on our more complex sentences, but believe that once we fully specify our coordination, embedded clause, information structure, and MC rules we will reduce the number of possible realizations.

###############################################################################
B. APPENDIX B: JUSTIFICATION OF PRESENT ANALYSIS OF INFORMATION STRUCTURE
###############################################################################

There is substantial disagreement within Algonquian linguistics about information structure.  The only general agreement is that obviation is important.  In Nishnaabemwin, new information typically precedes the verb and old information typically follows it (Valentine 2001, p. 952).  However, there are exceptions, and it is not clear why they occur (in some cases, the explanation could be that new referents following the verb are inferable from previous referents).  An analysis of East Cree, another Central Algonquian language, argues that word order preferences can be derived by various alignments of three hierarchies (Junker 2004, p. 360).  Using two of her hierarchies, I believe I can derive similar results for Nishnaabemwin.  Her analysis is done in the Minimalist framework, but I think the translation to HPSG would not be difficult.

Hierarchy 1: Proximate > Obviative
Hierarchy 2: Nouns NP1, NP2 adjoin on either side to a sentence S (verbs with pronominal affixes) at different levels S1 > S2 > S.  That is,

      S1
     / | \
(NP1) S2  (NP1)
     / | \
(NP2)  S  (NP2)

Only one each of NP1, NP2 is realized, so this gives possible orders of NP1-NP2-S, NP1-S-NP2, etc.  Now for the punchline: if these hierarchies are aligned, then everything is hunky-dory.  This corresponds to S1=Proximate and S2=Obviative (since S1 > S2 and Proximate > Obviative).  This gives us the word orders POS, OSP, PSO, and SOP.  If we break this alignment and have S1=Obviative and S2=Proximate, then we can also obtain the remaining two word orders: OPS and SPO.  Since the alignment is broken, these orders are dispreferred.

In East Cree, OPS is forbidden and SPO is dispreferred.  In Nishnaabemwin, verb-final is rare, and the only example I know of is POS.  Verb-initial is the most common, but Valentine (following Rhodes) regards SOP is the unmarked order.  Junker attributes these constraints to a third hierarchy, but I think there is a simpler explanation for Nishnaabemwin that also allows near-unambiguous assignment of information structure.

Russell claims that in Algonquian languages, obviation is a marker of non-topicality (Junker, p. 347).  Valentine uses numerous examples to show that in Nishnaabemwin, preverbal positions correspond to (left to right) topic, negation, and focus.  This would rule out OPS, since the obviated NP would have to be in topic position.  OPS is the only word order I do not have attestation of.  This also allows us to claim that in OSP, the obviated NP is in focus position and not topic position.  In POS, the proximate NP is the topic and the obviative NP the focus, which in PSO, the proximate NP could be in either topic or focus position.  In SPO and SOP, information structure is not marked.

This analysis rules out the only unattested word order (OPS) and explains the dispreference for SPO.  My hunch is that the apparent preference for verb-initial over verb-medial over verb-final is simply due to the unmarked order being used most often, followed by sentences in which one NP has been assigned topic or focus, followed by sentences in which both topic and focus are explicity marked.  It does not seem surprising that the latter is unusual.

References:
Valentine, J. Randolph. Nishnaabemwin Reference Grammar. 2001: U of Toronto Press, Toronto.
Junker, Marie-Odile. "Focus, obviation, and word order in East Cree". Lingua 114 (2004), pp. 345-365.
Russell, K. "Does obviation mark point of view?" In Nichols, J.D., Ogg, A.C. (Eds.), Studies in Honour of H.C. Wolfart, Memoir 13. 1996: Algonquian and Iroquoain Linguistics, Winnipeg.
