Ling 567 Lab 5
Nigel Kilmer and Woodley Packard

============
Phenomena:
============

A. Modification

Since Frisian has an adverb sentential negator, our grammar from the Matrix already contained some of the footwork for modification.  We added intersective modification rules for both prehead and posthead orders to rules.tdl:

adj-head-int := adj-head-int-phrase.
head-adj-int := head-adj-int-phrase.

A1. Adjectives

Adjectives in Frisian exhibit no agreement and come immediately before the noun that the modify (between the specifier and the noun, if present).  Multiple adjectives are allowed:

Source: author
Vetted: f
Judgment: g
Phenomena: adj
di gurt wunderbar soldaat sleept
di gurt wunderbar soldaat sliip-t
the big wonderful soldier sleep-3SG
the big wonderful soldier sleeps

# The adjective isn't in the correct position.
Source: author
Vetted: f
Judgment: u
Phenomena: adj
gurt di soldaat sleept
gurt di soldaat sliip-t
big the soldier sleep-3SG
the big soldier sleeps

To implement adjectives, we added an adjective-lex type which modifies a noun that has not yet taken its determiner, and is constrained to be POSTHEAD -, i.e. appear before the noun:

adjective-lex := basic-adjective-lex & intersective-mod-lex & norm-ltop-lex-item &
	[ SYNSEM [ LOCAL [ CAT [
		HEAD.MOD < [ LOCAL.CAT [ HEAD noun, VAL.SPR cons ] ] >,
		VAL [ SPR < >, SUBJ < >, COMPS < >, SPEC < > ],
		POSTHEAD - ] ] ] ].

gurt := adjective-lex &
  [ STEM < "gurt" >,
    SYNSEM.LKEYS.KEYREL.PRED "_big_a_rel" ].

The analysis works properly, in that the correct index appears as the ARG1 of the adjective predicate and forbidden word orders do not parse.

A2. Adverbs

Adverbs can appear just about anywhere -- before the verb, after the verb, and after complements are realized:

Source: author
Vetted: f
Judgment: g
Phenomena: adv
di soldaat sleept aural
di soldaat sliip-t aur.al
the soldier sleep-3SG over.all
the soldier sleeps everywhere

Source: author
Vetted: f
Judgment: g
Phenomena: adv
aural sleept di soldaat
aur.al sliip-t di soldaat
over.all sleep-3SG the soldier
the soldier sleeps everywhere

We added an adverb lexical type as suggested in the assignment:

adverb-lex := basic-adverb-lex & intersective-mod-lex &
	[ SYNSEM [ LOCAL [ CAT [
		HEAD.MOD < [ LOCAL.CAT [ HEAD verb ] ] >,
		VAL [ SPR < >, SUBJ < >, COMPS < >, SPEC < > ] ] ] ] ].

aural := adverb-lex &
  [ STEM < "aur.al" >,
    SYNSEM.LKEYS.KEYREL.PRED "_everywhere_a_rel" ].

Sentences containing this adverb parse, with the adverb predication having the correct ARG1, but in some positions there is an unwanted ambiguity about whether the adverb attaches low or high.  When attaching from the right, it needs to be able to attach either low or high in order to cover all positions, but when attaching from the left both options are available for the same word order.

Since the adverb 'aur.al' has a period in it in our orth-seg tier, we had to remove '\.' from the REPP tokenization pattern to be able to parse sentences containing it (in frr/repp/vanilla.rpp).

B. Agreement between adjectives and head nouns
Frisian does not exhibit any such agreement.

C. Demonstratives and markers of definiteness

C1. Definiteness is marked by the determiner in Frisian:

# definite
Source: author
Vetted: f
Judgment: g
Phenomena: {cogst, agr}
di soldaat sleept
di soldaat sliip-t
the soldier sleep-3SG
the soldier sleeps

# indefinite
Source: author
Vetted: f
Judgment: g
Phenomena: {cogst, agr}
en soldaat sleept
en soldaat sliip-t
a soldier sleep-3SG
a soldier sleeps

We added types for definite and indefinite determiners, which constrain the COG-ST of their index:

definite-determiner-lex := determiner-lex &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX [ COG-ST uniq+fam+act ] ].

indefinite-determiner-lex := determiner-lex &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX [ COG-ST type-id ] ].

Our determiner lexemes inherit from these types.

C2. Demonstratives

Frisian has a three-way demonstative distance distinction:

# far distal
Source: author
Vetted: f
Judgment: u
Phenomena: {cogst, agr}
ditdiar soldaat sleept
ditdiar soldaat sliip-t
the.there soldier sleep-3SG
that soldier sleeps

# medium distal
Source: author
Vetted: f
Judgment: g
Phenomena: {cogst, agr}
des soldaat sleept
des soldaat sliip-t
this/that soldier sleep-3SG
this/that soldier sleeps

# proximal
Source: author
Vetted: f
Judgment: g
Phenomena: {cogst, agr}
dijir soldaat sleept
dijir soldaat sliip-t
the.here soldier sleep-3SG
this soldier sleeps

We previously had posited three distinct quantifiers for the three levels of distance.  We now revise that to just one quantifier "exist_q_rel", supplemented by three modifying predicates:

demonstrative_a_rel := predsort.
proximal+dem_a_rel := demonstrative_a_rel.
distal+dem_a_rel := demonstrative_a_rel.
mid+dem_a_rel := distal+dem_a_rel.
far+dem_a_rel := distal+dem_a_rel.

To insert these predicates into the semantics, we enriched the hierarchy with some demonstrative determiner types.

The type 'demonst-determiner-lex' provides the exist_q_rel and stipulates the existance of a second EP, whose ARG1 is bound to the SPEC...INDEX and whose LBL is bound to the SPEC....LTOP.  The actual predicate for the second EP can be constrained easily on subtypes via the LKEYS.ALTKEYREL path.

demonst-determiner-lex := determiner-lex-supertype &
  [ SYNSEM [ LOCAL [ CONT.RELS <! [PRED "exist_q_rel"],
				  #akrel & arg1-ev-relation & [ LBL #lbl,
								ARG1 #arg1 ] !>,
                     CAT.VAL.SPEC.FIRST.LOCAL.CONT.HOOK [
                       INDEX #arg1 & [ COG-ST activ+fam ],
		       LTOP #lbl ] ],
	     LKEYS.ALTKEYREL #akrel] ].

Next, we created subtypes of demonst-determiner-lex for the three different distances, which constrain the predicate:

demonst-near-determiner-lex := demonst-determiner-lex &
  [ SYNSEM.LKEYS.ALTKEYREL.PRED proximal+dem_a_rel ].

demonst-mid-determiner-lex := demonst-determiner-lex &
  [ SYNSEM.LKEYS.ALTKEYREL.PRED mid+dem_a_rel ].

demonst-far-determiner-lex := demonst-determiner-lex &
  [ SYNSEM.LKEYS.ALTKEYREL.PRED far+dem_a_rel ].

We cross-classified these with the relevant gender distinctions to make types such as common-demonst-near-determiner-lex, and instantiated them with the correct surface forms:

common-demonst-near-determiner-lex := demonst-near-determiner-lex &
  [ SYNSEM.LOCAL.CAT.VAL.SPEC.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ GEND non-neuter,
								  PER 3rd ] ].

dijir := common-demonst-near-determiner-lex &
  [ STEM < "dijir" > ].

C3. Pronouns

We constrained our personal pronouns to be [COG-ST activ-or-more, SPECI + ] via the supertype `pronoun-noun-lex':

pronoun-noun-lex := no-spr-noun-lex &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX [ COG-ST activ-or-more, SPECI + ] ].

D. Argument Optionality

We realized that argument optionality is not formally restricted to 2SG pronouns, although these are by far the most commonly dropped. The formal restriction is, instead, that 1st person subjects cannot be dropped.  Subjects that are neither 1st person nor 2SG are only rarely dropped.  We revised our prior judgement of ungrammaticality on one of our testsuite examples that had a dropped 3SG subject:

Source: author
Vetted: f
Judgment: g
Phenomena: pro-d
heer gur slöpen
haa-t gur sliip-t
have-3SG good sleep-PST.PTCP
it slept well

To implement this, we reorganized the "person" type hierarchy to include a non-1st type, which 2nd and 3rd inherit from, and altered the constraint on the subject optionality rule type:

person := *top*.
1st := person.
non-1st := person.
2nd := non-1st.
3rd := non-1st.

context1-decl-head-opt-subj-phrase := decl-head-opt-subj-phrase &
  [ HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX [ PNG [ NUM singular,
                                                                           PER non-1st ] ] ].

It was not necessary to constrain COG-ST for this construction, since it is already constrained to in-foc on the rule's supertype basic-head-opt-subj-phrase.

We seem to be having trouble parsing sentences with dropped subjects and auxilliaries.  We get a spanning analysis with [MC na].  We are not yet sure what to blame for this.  Sentences with dropped subjects and no auxilliaries work fine.

============
= Coverage =
============

As noted above, we had to modify the grammaticality judgement on one item in our test suite.  The baseline numbers here are with last week's grammar on this revised test suite.

At the end of lab4, our coverage on our test suite was 48.1% of positive items (51 / 106).
We overgenerated on 9.8% of negative items (5 / 51).

At the end of lab5, our coverage on our test suite is 50.9% of positive items (54 / 106).
We overgenerate on 9.8% of negative items (5 / 51).

The improved coverage is due to the analysis of adjectives and adverbs.

Ambiguity levels did not change on any sentences (other than the ones that went from unparsable to parsable).

==========
= Corpus =
==========

Our test corpus comes from a book of folk tales:

Uald söld'ring tialen.  Christian Peter Hansen, 1858.

We used the first 20 sentences from the first tale, which seems to be about the adventures of some sea captains.  We attempted to perform morphological analysis, since our grammar targets the orth-seg tier; however, we are not completely confident of our analyses, since some of the lexical material is not covered by our reference grammar.

We cannot currently parse any of these sentences.  We do not even have lexical coverage on any of them.
