Ling 567 Lab 6
Nigel Kilmer and Woodley Packard

============================================================
Phenomena
============================================================

A. Matrix yes/no questions.

Yes-no questions are marked in Frisian by moving the finite verb to sentence initial position. The following two examples show this contrast:

Source: a:277
Vetted: s
Judgment: g
Phenomena: q
wet dü jir bliiv
wel-st dü jir bliiv
want-2SG you here stay
do you want to stay here?

Source: author
Vetted: f
Judgment: g
Phenomena: wo
dü wet jir bliiv
dü wel-st jir bliiv
you want-2SG here stay
you want to stay here

It seems that the finite verb is often an auxiliary, though this is not required. Here is an example that uses an auxiliary:

Source: a:277
Vetted: s
Judgment: g
Phenomena: q
skel ik di en stek me.dö
skel ik di en stek me.dö
shall I you a piece with.do
shall I give you a piece to take along?

Negative questions are constructed in a manner consistent with what we know about the placement of the negation adverb and the location of the finite verb in question word order:

Source: author
Vetted: f
Judgment: g
Phenomena: q
et      hi höm ek
iit-t   hi höm ek
eat-3SG he it.OBJ not
does he not eat it?

The following changes were made to the tdl for yes/no questions:

The subj-v-inv-lrule was not copying the value of INFLECTED, so that was added to the tdl.

subj-v-inv-lrule := ...
  [ ...
    INFLECTED #inf,
    DTR [ ...
          INFLECTED #inf ] ].

The complement-head rules were able to apply even after the inversion rule had applied, which was leading to parses of 'questions' that didn't have the verb in initial position. (That is, declaratives were parsed as questions.) To fix this, a type called uninverted was added which the complement-head rules now inherit from:

uninverted := sign & [ SYNSEM.LOCAL.CAT.HEAD.INV - ].
comp-head-phrase := basic-head-1st-comp-phrase & head-final-head-nexus & uninverted.
comp-head-phrase-2 := basic-head-2nd-comp-phrase & head-final-head-nexus & uninverted.

The modification rules added in lab 5 did not copy the MC feature up, so the inv rule was able to apply in places it shouldn't. To fix this, the following was appended to head-mod-phrase:

head-mod-phrase :+ [ SYNSEM.LOCAL.CAT.MC #mc, HEAD-DTR.SYNSEM.LOCAL.CAT.MC #mc ].

That still leaves it ambiguous as to whether the 'int' rule applies before or after modification rules. To specify that 'int' has to apply higher in the tree than modification, a feature IS-INT was added. The 'int' rule sets this to +, and head-mod-phrase now requires this to be - on the head daugher.

head-mod-phrase :+ [ HEAD-DTR.IS-INT - ].

------------------------------------------------------------

B. Embedded clauses.

Embedded clauses that are the complements of certain verbs usually occur with a complementizer. It is unclear whether the complementizer is required, since our source only mentions that they are optional for quotatives, and no non-quotative examples without a complementizer could be found. For declarative embedded clauses, the complementizer "dat" is used. The word order inside embedded clauses is more free than in matrix clauses, as the main verb can be in V2 position, at the end of the clause, or near the end of the clause with modifiers after it. Verb-initial word order still seems to be prohibited though.

# Adapted from a:295
Source: author
Vetted: f
Judgment: g
Phenomena: emb-d
ik gesi dat et sa es
ik gesi dat et sa sen-t
I guess that it so be-3SG
I guess that is so

Source: author
Vetted: f
Judgment: g
Phenomena: emb-d
ik gesi dat et es sa
ik gesi dat et sen-t sa
I guess that it be-3SG so
I guess that is so

Source: author
Vetted: f
Judgment: u
Phenomena: emb-d
ik gesi dat es et sa
ik gesi dat sen-t et sa
I guess that be-3SG it so
I guess that is so

Verbs such as "weet" (know) can take an embedded interrogative clause, as in this example:

Source: author
Vetted: f
Judgment: g
Phenomena: emb-q
ik weet ek weder det Russisch wiar
ik weet ek weder det Russisch sen-t
I know not whether that Russian be-PRET
I don't know whether that was Russian

The complementizers that are used for yes-no interrogatives are "weder" (whether) and "of" (also glossed as whether).

There is a distinction between verbs that accept declarative versus interrogative embedded clauses. The verb "gesi" (guess) is one that can not occur with an embedded interrogative:

Source: author
Vetted: f
Judgment: u
Phenomena: emb-q
ik gesi weder det Russisch wiar
ik gesi weder det Russisch sen-t
I guess whether that Russian be-PRET
I guess whether that was Russian

In order to handle verbs that take embedded clauses as an argument, the following three types were created:

emb-clause-verb-lex := main-verb-lex & clausal-second-arg-trans-lex-item &
  [ SYNSEM.LOCAL.CAT [ VAL.COMPS < #comp & [ LOCAL [ CAT.HEAD comp,
			 	    		     CONT.HOOK.INDEX.SF prop-or-ques ] ] > ],
    ARG-ST < [ ], #comp > ].

dec-emb-clause-verb-lex := emb-clause-verb-lex &
  [ SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL.CONT.HOOK.INDEX.SF prop ] > ].

int-emb-clause-verb-lex := emb-clause-verb-lex &
  [ SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL.CONT.HOOK.INDEX.SF ques ] > ].

Two verbs, "gesi" (guess) and "weet" (know) were added to the lexicon using these new types. Since "gesi" can only take a declarative clause, it inherits from dec-emb-clause-verb-lex, and since "weet" can take either a declarative or interrogative clause, it inherits from the base type.

gesi := dec-emb-clause-verb-lex &
  [ STEM < "gesi" >,
    SYNSEM.LKEYS.KEYREL.PRED "_guess_v_rel" ].

weet := emb-clause-verb-lex &
  [ STEM < "weet" >,
    SYNSEM.LKEYS.KEYREL.PRED "_know_v_rel" ].

To handle complementizers, these types were added:

complementizer-lex-item := raise-sem-lex-item & basic-one-arg &
  [ SYNSEM.LOCAL.CAT [ VAL [ SUBJ < >,
			     COMPS < #comps >,
			     SPR < >,
			     SPEC < > ],
		       HEAD comp ],
    ARG-ST < #comps > ].

dec-complementizer-lex-item := complementizer-lex-item &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.SF prop ].

int-complementizer-lex-item := complementizer-lex-item &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.SF ques ].

Then the complementizers that correspond to declarative and interrogative clauses were added to the lexicon:

dat := dec-complementizer-lex-item &
  [ STEM < "dat" > ].

weder := int-complementizer-lex-item &
  [ STEM < "weder" > ].

To assist with generation, these trigger rules were added to trigger.mtr:

dat_gtr := generator_rule &
[ CONTEXT [ RELS <! [ ARG2 #h & handle ],
		    [ ARG0 #e & event ] !> ],
  FLAGS [ EQUAL < #e, #h >,
	  TRIGGER "dat" ] ].

weder_gtr := generator_rule &
[ CONTEXT [ RELS <! [ ARG2 #h & handle ],
		    [ ARG0 #e & event ] !> ],
  FLAGS [ EQUAL < #e, #h >,
	  TRIGGER "weder" ] ].

After these additions, it was possible to parse sentences with V2 word order in the embedded clause, but verb-final order wasn't working. Verb-initial order *was* (and is still) working, even though it shouldn't. In order to fix verb-final order, we added a new pair of comp-head and subj-head phrases that only work in embedded [ MC - ] clauses.

comp-head-phrase-emb := basic-head-1st-comp-phrase & head-final-head-nexus &
  [ SYNSEM.LOCAL.CAT.MC - ].

head-final-head-emb := head-final &
  [ SYNSEM.LOCAL.CAT.MC -,
    HEAD-DTR.SYNSEM.LOCAL.CAT.MC - ].

subj-head-phrase-emb := decl-head-subj-phrase & head-final-head-emb.

The new comp-head-phrase-emb allows head-final word order, so it's obviously necessary. The reason for adding subj-head-phrase-emb is that the other subj-head rules wouldn't work once the MC value had been constrained to - (they have [ MC na ]), so it was necessary to create a new one specific to embedded clauses.

In an attempt to prevent inversion from occuring inside embedded clauses, which is one of the reasons for verb-initial order being allowed by the grammar inside embedded clauses, I added MC + to the inversion rule. However, this seems to prevent it from ever being allowed, I assume because of the restriction on many other rules to have MC na. The other reason for verb-initial order being allowed inside embedded clauses is due to the 'nexus' rule types that seem to be used to implement V2 word order by the customization system. The head-initial-head-nexus type looks like this:

head-initial-head-nexus := head-initial &
  [ SYNSEM.LOCAL.CAT.MC na & #mc,
    HEAD-DTR.SYNSEM.LOCAL.CAT.MC #mc ].

And the head-subj rule (which should not be allowed to apply if the verb doesn't have something to its left) inherits this. Since the MC value doesn't need to end up being MC + inside embedded clauses, the head-subj and head-comp rules are allowed to apply without regard for a lack of arguments to the left.

Another problem - while parsing of sentences with embedded clauses seems to work great apart from allowing verb-initial order, trying to generate gives an error: "edge limit exhausted".

It seems that some rule is able to apply infinitely in generation but not in parsing. I'm not sure why this would be or how to debug it. I'll post to GoPost with more information (not sure what would be helpful though) to try to resolve this next week.

------------------------------------------------------------

C. Non-verbal predicates.

Noun phrases, adjective phrases, and prepositional phrases can all be predicates in Frisian. The obligatory copula is an inflected form of either "wiis" (to be) or "uur" (to become).

# copula+PP
Source: a:235
Vetted: s
Judgment: g
Phenomena: cop
jü es fan Langeness
jü wiis-t fan Langeness
she is-3SG from Langeness
she's from Langeness

# copula+AdjP
Source: a:238
Vetted: s
Judgment: g
Phenomena: cop
en hi wiar gans, verrückt eeder Motor.räder
en hi wiis-t gans verrückt eeder Motor.räder
and he was-PAST whole crazy after motor.cycles
and he was really crazy about motorcycles

# copula+Adj
Source: author
Vetted: f
Judgment: g
Phenomena: cop
hi es gurt
hi wiis-t gurt
he is-3SG big
he is big

# copula+NP
Source: a:239
Vetted: s
Judgment: g
Phenomena: cop
min mooter wiar en hoog.dütsk.en
min mooter wiis-t en hoog.dütsk.en
my mother was-PAST a high.German.NOM
my mother was a (speaker of) High German

An example using "uur":

Source: a:238
Vetted: s
Judgment: g
Phenomena: cop
hi uur nü tö hārefst aacht.en.tachentig
hi uur-t nü tö hārefst aacht.en.tachentig
he become-3SG now to autumn eight.and.eighty
he'll be eighty-eight in the fall

Prepositional phrases were implemented by creating a lexical type 'prep-lex':

prep-lex := basic-int-mod-adposition-lex & attrib-or-pred-lex-item &
	[ SYNSEM.LOCAL.CAT [
	    HEAD.MOD < [ LOCAL.CAT.HEAD +nv ] >,
	    VAL [
		COMPS < [ LOCAL.CAT [	HEAD noun & [ CASE obj ],
				VAL [ SPR < >, SUBJ < >, COMPS < >, SPEC < > ] ] ] >,
		SPR < >, SUBJ < >, SPEC < > ] ] ].

The valence of the modified element was not constrained in order to allow PPs to attach anywhere as an adverbial.

Lexical entries were added for a few prepositions:

ön := prep-lex &
  [ STEM < "ön" >,
    SYNSEM.LKEYS.KEYREL.PRED "_in_p_rel" ].

bi := prep-lex &
  [ STEM < "bi" >,
    SYNSEM.LKEYS.KEYREL.PRED "_by_p_rel" ].

fan := prep-lex &
  [ STEM < "fan" >,
    SYNSEM.LKEYS.KEYREL.PRED "_from_p_rel" ].

At this point sentences containing PP modifiers could be parsed.

The copula that takes an AdjP or PP complement was added:

copula-lex := verb-lex & trans-first-arg-raising-lex-item-2 &
  [ SYNSEM.LOCAL [ CAT [ HEAD verb & [ AUX -] ,
                         VAL [ SPR < >,
                               SPEC < >,
                               SUBJ < #subj >,
                               COMPS < #pred > ] ] ],
    ARG-ST < #subj &
                 [ LOCAL [ CAT [ HEAD noun,
                                 VAL [ SPR < >,
                                     COMPS < > ] ] ] ],
             #pred &
                 [ LOCAL [ CAT [ HEAD +jp,
                               VAL [ SPR < >, COMPS < > ] ] ] ] > ].

wiis := copula-lex &
  [ STEM < "wiis" > ].

This type works like a regular transitive verb, except its complement is [ HEAD +jp ] instead of [ HEAD noun ], and it doesn't introduce a predication -- instead it makes its head daughter's EP work like the main EP, by inheriting from trans-first-arg-raising-lex-item-2. To make this work, adjectives and prepositions now inherit from attrib-or-pred-lex-item, which links the XARG to the entity being modified.

Finally, the copula that takes an NP complement was added. This uses the regular transitive verb type, and this lexical entry:

wiis-np-cop := transitive-verb-verb-lex &
  [ STEM < "wiis" >,
    SYNSEM.LKEYS.KEYREL.PRED "be_v_id_rel" ].

------------------------------------------------------------

D. Coordination.

Verbal coordination was too unconstrained, and there were a lot of unnecessary parses.

Constraints were added to vp-coord-phrase and vp-bottom-coord-phrase to pass up the values of MC, INV, and HEAD.FORM. Constraints were added to s-coord-phrase and s-bottom-coord-phrase to pass up the values of MC and INV. This brought the number of parses of a simple coordinated-VP sentence from 32 to 10, and all of the 10 parses seem validly ambiguous.

------------------------------------------------------------

E. Other changes.

- The lexical type for 'fuul', nodet-singular-noun-noun-lex, failed to specify its namesake constraint (singularity). I added it. I also added [ PER 3rd ]. Together these constraints cut the number of readings for "di soldaat-en liir fuul" from 3 to 1 (the bad ones had fuul as the subject of liir, either as plural or as 1sg). It also removed one of the remaining 2 parsed ungrammatical items, surprisingly (namely "di soldaat-en fuul liir").

- Changed "gur" from adjective-lex to adverb-lex, since it seems to always be used as an adverb in our testsuite. This increased coverage by 4 items (each with an ambiguity of 2, since "gur" can currently either attach to the auxilliary or to the main verb).

- Added lexemes 'miaren' (adverb), 'wunderbar' (adjective), 'hingst' (noun), 'stek' (noun), 'smile' (verb).

- There were two testsuite items where 'fuul' was misspelled as 'full', and two places where 'molk' was misspelled 'milk'. Fixed.

- There was one place where the tag -PRET appeared on the Frisian side of the IGT -- I changed it to -t.

- Some of the examples for embedded clauses were syntactically complicated inside the embedded clause, so I changed it to simple clauses with a transitive verb and pronouns.

============================================================
Testsuite
============================================================

Baseline coverage: 51.4%
Baseline overgeneration: 9.6%

Current coverage: 63.8%
Current overgeneration: 3.8%
