Lab 8
Language: Miyako
Adam Ledyard and Sanae Sato

Switch from orth line to orth-seg:

	We switch parsing from the orth line to orth-seg to cut down on
	generation since there are multiple surface	forms of affixs and 
	verb stems that are both phonologically conditioned and 
	morphologically conditioned.  We are operating under the assumption 
	of a morphological analyzer now and this cut down on generation 
	massively. We removed the multiple stems of the same word and 
	affix in the lexicon as a result.  We were still getting
	more generation that was needed and and the turning on and 
	editing of semi.vpm cut it down to single generation!

semi.vpm additions:

	The semi.vpm was no up to date on the evidentials so that feature was added:

		EV : EV
	  	reportative <> reportative
	  	quotative <> quototative
	  	noevid << [e]

	As you can see we also added noevid, noaspect and nomood to the heirarchy.  
	This is defined in the grammar but we make no use of it in any rules so 
	it's only for generation purposes.

	  	nomood << [e]
	  	noaspect << [e]


	All of these additions plus another trigger rule for the reportative clitic:
		
		ca_gr := generator_rule &
  		   [ CONTEXT.RELS <! [ ARG0.EV reportative ] !>,
    		     FLAGS.TRIGGER "ca" ].

	resulted in single generations of sentences.  So for example:

		vva=ga idi-tar=(ca)
		you=NOM exit-PAST=(REPORT)
		(I heard) you left.

	generated a single utterance:
		
		vva ga idi-TAR ca


Translation from English "Dogs sleep":

	We added the appropriate lines to the lkb files and were able to 
	generate the correct utterance:

		in=nu niv-r
		dog=NOM sleep-NPST

	We originally got two generations with the pronoun nominalizer "ga" and the
	non-pronoun nominalizer "nu". To fix this we added a constraint the cnoun 
	lexical type to specify it as PRONOUN -.  This got rid of the extraneous generation.



From Lab6 - Embedded Clause/Complementizer
	We finally fixed embedded clause/complementizer in our grammar. 

	1. IGT 
	Here is the example sentence from test suite.(=ru is the complementizer):

		cf-tar=ru=u ss-tar
		cf-tar=ru=u ss-tar
		arrive-PAST=COMP=ACC know-PAST
		I realized [the fact that] (she) arrived.

	2. Implementation

	We added lexical rule for verbs (clause-embedding verbs). 
	And created subtype for each to be able to work with both "prop" and "ques" mode. 

	miyako.tdl
	--------
	emb-verb-lex := main-verb-lex & clausal-second-arg-trans-lex-item &  PRE-or-converb-rule-dtr & MOOD-rule-dtr & TENSE-rule-dtr & negation-rule-dtr &
	  [ INFLECTED.TENSE-FLAG -,
    	SYNSEM.LOCAL.CAT [ HEAD [ MOD < >,
	                              VCLASS - ], 
	                       VAL  [ COMPS < #comp &
	                                        [LOCAL [CAT [HEAD adp,
	                                                     VAL.COMPS <>],     
	                                         CONT.HOOK.INDEX.SF prop-or-ques],
	                                       OPT-CS type-id ]>]],             
	   ARG-ST.REST.FIRST #comp ].
	
	prop-emb-verb-lex := emb-verb-lex &
	  [SYNSEM.LOCAL.CAT.VAL.COMPS <[LOCAL.CONT.HOOK.INDEX.SF prop]>].
	
	ques-emb-verb-lex := emb-verb-lex &
	  [SYNSEM.LOCAL.CAT.VAL.COMPS <[LOCAL.CONT.HOOK.INDEX.SF ques]>].
	--------

	lexicon.tdl
	--------
	ss_2 := prop-emb-verb-lex &
   	[ STEM < "ss" >,
	     SYNSEM.LKEYS.KEYREL.PRED "_know_v_rel" ].
	--------

	Also, in order for P (i.e. =u ) that attaches to the CP to pass up 
	LTOP & INDEX values (to get proper HCON at the end), we added 
	following to the existing case-marking-lex as follows:

	miyako.tdl
	--------
	case-marking-lex := basic-one-arg & raise-sem-lex-item &
	  [ SYNSEM.LOCAL [ CAT [ HEAD adp &
                            	[ CASE #case,
	                              MOD < > ],
	                       VAL [ SPR < >,
	                             SUBJ < >,
	                             COMPS < #comps >,
	                             SPEC < > ] ],
	                    CONT.HOOK [ INDEX #index,
	                                LTOP #ltop] ],
	    ARG-ST < #comps &
	             [ LOCAL [ CAT [ HEAD +nc &
	                                [ CASE #case ],
	                             VAL.SPR < > ],
	                       CONT.HOOK [ INDEX #index,
	                                   LTOP #ltop]]] > ].
	--------


-----
One sentence from the test corpus:  The Causal Clitic (-ba)

	1. IGT 
	We selected the following sentence (the causal clitic -ba):

		uri=a zzu jai-ba kurus-tar.
		uri=a žžu ja-i-ba, kurus-tar.
		3SG=TOP fish COP-THM-CVB.CSL, kill-PAST.
		Since it was a fish, (he) killed (it).

	2. The causal clitic (-ba affix)
	As for the implementation, -ba affix functions as a subordinating 
	conjunction (similar to "since" in English). This new lexical rule 
	fills in FORM feature of verbs which attaches the -ba affix. 
	The FORM feature reflects the presence of the causal clitic to 
	the newly added unary rule higher in the tree, so that it will 
	select proper daughter.

	irules.tdl
	--------
	causal-suffix :=
	%suffix (* -ba)
	causal-lex-rule.
	--------

	miyako.tdl
	--------
	causal-lex-rule :=  add-only-no-ccont-rule & infl-lex-rule &
	  [ INFLECTED.TENSE-FLAG +,
	    DTR PRE-or-converb-rule-dtr,
	    SYNSEM.LOCAL.CAT.HEAD.FORM nonfinite ].
	--------

	To prevent overgeneration with this unary rule, we needed other verbs to have a FORM value
	that was not nonfinite.  Therefore we created a type:
	
		non-converb-phrase := phrase &
		 [ SYNSEM.LOCAL.CAT.HEAD.FORM finite ].

	This was then inherited by the TENSE inflectional rule since tense is obligatory
	for non-converb verb phrases.  Tense is not seen with the converbs so this FORM values
	parrallel a fact seen in the grammar. The bare np predicate type also inherited it.
	
	---------
	
	3. The unary rule
	The newly added unary rule (mentioned briefly above) takes a -ba marked complete sentence 
	and return a constituent with empty VAL features and a non-empty MOD list, 
	so that -ba marked sentence can fills a modifier slot of another clause. 
	The C-CONT of this rule will introduce a two-place relation which relates 
	its ARG1 and ARG2 to the LTOPs of the daughter and the MOD value via qeqs. 
	
	rules.tdl
	--------
	converb-cl := converb-cl.
	--------

	miyako.tdl
	--------
	converb-cl := same-ynq-unary-phrase  &
	 [ SYNSEM.LOCAL.CAT [ VAL #val,
			      HEAD verb &
	                           [FORM nonfinite,
	                            MOD < [LOCAL[CAT.VAL.SUBJ <>,
	                                         CONT.HOOK.LTOP #mod]] >] ],
	   C-CONT [HCONS <!  qeq &
	                    [HARG #arg1,
	                     LARG #ltop],
	                    qeq &
	                   [HARG #arg2,
	                     LARG #mod]!>,
	           RELS <! event-relation &
	                   [ PRED "causal_rel",
	                     ARG1 #arg1,
	                     ARG2 #arg2 ] !>],
	   ARGS < [SYNSEM.LOCAL [ CAT [ HEAD  verb &
	                                     [ FORM nonfinite,
	                                       MOD <>],
				         VAL  #val &
				               [ SUBJ < >,
					         COMPS < >,
					         SPR < > ]],
	                             CONT.HOOK.LTOP #ltop]]>].
	--------

	4. Analysis
	

	We are now getting 76.4 percent which is up from the 70.9 percent coverage
	from the Lab7 grammar. The number of analyses went down	from 3.44 to 1.13
	which means we cut down quite a bit on ambiguity.
	
	Some problems that we are seeing are with the focus marker 'du' and the 
	nominal coordination.  The coordination of the nouns in a sentence like:
	
			Source: author
			Vetted: f
			Judgment: g
			Phenomena: crd
			pztu=tu midum=tu iditar
			pztu=tu midum=tu idi-tar
			man=ASC woman=ASC exit-PAST
			A man and a woman exited

	is not parsing.  The coordination seems to be working but the VP is not
	attaching. We ran out of time to do any kind of work on this but this will
	be addressed next week.  
	
	There is also some ambiguity with the 'du' focus marker where it's attaching
	in to the left of the verb.  We had orginally fixed this with the POSTHEAD
	value but something seems to be overriding this.  This will also be looked at
	in the next lab.
	
	
