Jason Shaw 
Prescott Klassen (author)
LING 567
Lab 7
2/19/10

This writeup will be organized into four sections:
I. A descriptive statement of the grammatical facts of Nishnaabemwin.
II. A statement of how we implemented the phenomena for this week: "I can eat glass. It doesn't hurt me."
III. A statement of additional fixes we made to the grammar this week to reduce ambiguity: refactoring the verb inflection pipeline and the YNQ feature
IV. Generation
V. A summary of the current coverage of the grammar over our test suite.


I. THE FACTS OF NISHNAABEMWIN

The following are the grammatical facts of Nishnaabemwin relevant through Lab 7 (this is nearly identical to the statement in Lab 6, with one addition to address embedded questions):

I. Verbs

a. There are 4 main classes of verbs in Nishnaabemwin, each with their own inflectional paradigm:

VAI - Intransitive verb with animate subject
VII - Intransitive verb with inanimate subject
VTA - Transitive verb with animate object
VTI - Intransitive verb with inanimate object

b. Verbs have 3 orders:
- Independent (main clause)
- Conjunct (wh-questions, sentential complements, etc.)
- Imperative.

We are covering independent order for matrix clauses and conjunct order for embedded clauses.

c. Direct/Inverse

VTA verbs in Nishnaabemwin are direct/inverse, which means that a suffix on the verb specifies the relation between the subject and object. We have incorporated direct/inverse into our VTA lexical rules.

d. Inflection

The verb carries a lot of information in Nishnaabemwin. It is inflected for person/gender/number (for both subject and object in transitive verbs), aspect, tense, negation, direct/inverse theme, and in order for independent and conjunct.

II. Person/Number/Gender

Nishnaabemwin has 1st, 2nd, 3rd, and unspecified actor persons. We cover 1st, 2nd and 3rd in our grammar. Number is singular or plural.  Gender is animate or inanimate. Nishnaabemwin also distinguishes between inclusive and exclusive first-person pluarl, but we do not cover this in our grammar.

III. Other Features

Nishnaabemwin nouns and inflection on verbs also reflect proximate and obviative relations to foregrounding and backgrounding of subject/object. Our grammar includes this other feature in our inflection of both nouns and verbs.  Additionally, nouns can take a locative suffix and be used in copular constructions to approximate what is accomplished with prepositional phrases in English.

IV. Agreement

Nouns and verbs agree in person, number, gender, and obviation.

V. Prenouns

"Prenoun" is a term our reference author uses to describe lexical items which attach to the fronts of nouns and behave syntactically like prefixes, yet are not subject to the same phonological processes as other types of prefixes.  We have chosen to treat prenouns as individual words instead of inflections on nouns. Semantically, prenouns are most like adjectives.

VI. Demonstrative Pronouns

There are no real determiners in Nishnaabemwin, no real way to say "the" or "a". We have chosen to classify demonstrative pronouns in Nishnaabemwin as determiners and demonstrative that describe distal relations between speaker and subject. There are three categories of distance, proximal, distal, and remote. Our demonstrative pronouns (classified as determiners) incorporate this into their semantics.

VII. Negation

There is a distinct adverb gaawii and a required verbal suffix that indicate negation. The adverb is optional, especially in casual usage, but the suffix is not.

VIII. Yes/No

The particle "na" is used for yes/no questions and must be in the second position in the sentence.  The item which precedes it is the item being questioned.  In our grammar we treat "na" as a clitic which assigns interrogative force to its clause.

IX. Embedded Clauses

Embedded clauses in Nishnaabemwin are indicated by an optional complementizer as well as distinct inflectional paradigms.  Embedded clauses normally follow the verbs which introduce them, but this is not always the case.  We have found no evidence that the "na" particle which marks polar questions can appear in embedded clauses.  It is possible that Nishnaabemwin only "embeds" questions by means of direct quotation.  That is, the only mechanism may be analagous to "I wonder, 'What is his name?'"

X. Non-verbal predicates

Expressions of identity and location in Nishnaabemwin are accomplished with various copulas.  These inflect like normal intransitive verbs, but have multiple arguments, so we treat them as a separate verb type.  Expressions of identity, which correspond to NP predicates in other languages, use the animate verb "aawi" or the inanimate verb "aawan".  Expressions of location, which correspond to PP predicates in other languages use the animate/inanimate pairs "yaa"/"yaamgad", "dgo"/"dgomgad", and "bi"/"te", which all have similar semantics in their locational usage.  The word order in these sentences is free.  Where other languages express concepts with AP predicates, Nishnaabemwin uses stative verbs or nominal prefixes.

II.  IMPLEMENTATION OF LAB 7 PHENOMENA - "I can eat glass. It doesn't hurt me."

Our plan for editing the grammar to deal with the two sentences, "I can eat glass." and "It doesn't hurt me." was to add missing lexicon entries based on the Rhodes Ojibwe Dictionary and add modal 'can' to our verb inflection pipeline based on the prefix "-daa" described in our Reference Grammar (Valentine, 2001).

The following lexicon items were added:

mwaad := verb-class-VTA-verb-lex &
  [ STEM < "mwaad" >,
    SYNSEM.LKEYS.KEYREL.PRED "_eat_v_rel" ].

waasechganaabik := class4a-anim-noun-lex &
  [ STEM < "waasechganaabik" >,
    SYNSEM.LKEYS.KEYREL.PRED "_glass_n_rel" ].

gzhikwaad := verb-class-VTA-verb-lex &
  [ STEM < "gzhikwaad" >,
    SYNSEM.LKEYS.KEYREL.PRED "_hurt_v_rel" ].

We also added three new test sentences to our test suite:

#352	
Source: author
Vetted: f
Judgment: g
Phenomena: tam
Niin nmwaawaa waasechganaabik
Niin n-doo-mwaad-aa-0 waasechganaabik
I.AN.1SG AC.1SG-PRES-eat+something-DIR.THM-GL.3SG glass.AN.3SG
"I eat glass"

#353	
Source: author
Vetted: f
Judgment: g
Phenomena: tam
Wiin ngzhikwigw niin
Wiin n-doo-gzhikwaad-igw-sii-0 niin
It.AN.3SG GL.1SG-PRES-eat+something-INV.THM-NEG-AC.3SG glass.AN.3SG
"It doesn't hurt me"

#353	
Source: author
Vetted: f
Judgment: g
Phenomena: tam
Niin nmwaawaa waasechganaabik
Niin n-daa-doo-mwaad-aa-0 waasechganaabik
I.AN.1SG AC.1SG-can-PRES-eat+something-DIR.THM-GL.3SG glass.AN.3SG
"I can eat glass"
 
Because we had added negation as a suffix in a previous lab, the second sentence "It doesn't hurt me" required no changes:

;;; VTA Negation (from Nishnaabemwin.tdl)

vta-negation-rule-dtr := word-or-lexrule.

vta-negation-lex-rule := vta-tense-rule-dtr & infl-cont-change-only-ltol-rule & vta-aspect-rule-dtr &
  [ DTR vta-negation-rule-dtr ].


vta-negation-morph-lex-rule := vta-negation-lex-rule &
  [ C-CONT [ HOOK [ XARG #xarg,
                    LTOP #ltop,
                    INDEX #ind ],
             RELS <! event-relation &
                     [ PRED "_neg_r_rel",
                       LBL #ltop,
                       ARG1 #harg ] !>,
             HCONS <! qeq &
                      [ HARG #harg,
                        LARG #larg ] !> ],
    SYNSEM.LKEYS #lkeys,
    DTR.SYNSEM [ LKEYS #lkeys,
                 LOCAL [ CONT.HOOK [ XARG #xarg,
                                     INDEX #ind,
                                     LTOP #larg ],
                         CAT.HEAD verb ] ] ].

(from irules.tdl)

vta-negation-morph-suffix :=
%suffix (* -sii)
vta-negation-morph-lex-rule.

Creating a new step in the verb inflection pipeline for "-daa" followed the same pattern:

;;; VTA Modal Can (from Nishnaabemwin.tdl)

vta-modal-rule-dtr := word-or-lexrule.

vta-modal-lex-rule := infl-cont-change-only-ltol-rule & vta-person-prefix-rule-dtr &
  [ DTR vta-modal-rule-dtr ].

vta-modal-morph-lex-rule := vta-modal-lex-rule &
  [ C-CONT [ HOOK [ XARG #xarg,
                    LTOP #ltop,
                    INDEX #ind ],
             RELS <! event-relation &
                     [ PRED "_can_v_rel",
                       LBL #ltop,
                       ARG1 #harg ] !>,
             HCONS <! qeq &
                      [ HARG #harg,
                        LARG #larg ] !> ],
    SYNSEM.LKEYS #lkeys,
    DTR.SYNSEM [ LKEYS #lkeys,
                 LOCAL [ CONT.HOOK [ XARG #xarg,
                                     INDEX #ind,
                                     LTOP #larg ],
                         CAT.HEAD verb ] ] ].

(from irules.tdl)

vta-modal-morph-prefix :=
%prefix (* daa-)
vta-modal-morph-lex-rule.

Adding a new inflection rule to the verb inflection pipeline required hand-editing the tdl and positioning "modal 'can'" between the tense rule and the person-prefix-rule.

vta-tense-lex-rule := infl-add-only-no-ccont-ltol-rule & vta-modal-rule-dtr & vta-person-prefix-rule-dtr &
  [ DTR vta-tense-rule-dtr ].

vta-person-prefix-rule-dtr := word-or-lexrule.

vta-person-prefix-lex-rule := infl-add-only-no-ccont-ltol-rule & vta-modal-rule-dtr & vta-tense-rule-dtr &
  [ DTR vta-person-prefix-rule-dtr ].

The following MRS was generated for "I can eat glass"

h1 e2 { prop-or-ques present aspect mood semsort }
{ h3:_i_prn_rel(x4{ semsort + activ+fam 1sg anim obviation})
  h5:exist_q_rel(x4, h6, h7)  
  h8:_eat_v_rel(e2, x4, x9 { semsort 3sg anim prox cog-st bool })
  h1:_can_v_rel(e11 { tense, aspect, mood, iforce, semsort}, h10)
  h12:_glass_n_rel(x9)
  h13:exist_q_rel(x9, h14, h15) }
{ h6 = q h3 h10 = q h8 h14 = q h12 }


The following MRS was generated for "It doesn't hurt me."

h1 e2 { prop-or-ques present aspect mood semsort }
{ h3:_he+she+or+it_prn_rel(x4{ semsort + activ+fam 3sg anim obv})
  h5:exist_q_rel(x4, h6, h7)  
  h8:_hurt_v_rel(e2, x4, x9 { semsort 1sg anim obviation activ+fam cog-st + })
  h1:_neg_r_rel(e11 { tense, aspect, mood, iforce, semsort}, h10)
  h12:_i_prn_rel(x9)
  h13:exist_q_rel(x9, h14, h15) }
{ h6 = q h3 h10 = q h8 h14 = q h12 }


III.  ADDITIONAL FIXES

After Lab 6, there were two major sources of ambiguity in our grammar: the verbal inflection pipeline, and our implementation of polar questions.  Below, we  describe the changes we made to both aspects of our grammar to dramatically reduce the average number of parses per sentence over our test suite.

POLAR QUESTIONS

In order to implement polar questions, we had introduced a new non-local feature, [ YNQ 0-1-dlist ], that tracked whether the sentence-initial word had acquired a question-marking clitic.  The clitic is [ YNQ 1-dlist ].  If the clitic appears, then [ YNQ 1-dlist ] propagates up the tree so that roots of questions are [ YNQ 1-dlist ] and roots of declarative sentences are [ YNQ 0-dlist ].  Since only the clitic is [ YNQ 1-dlist ] , the vast majority of words must be [ YNQ 0-dlist ].  We had insufficiently constrained our lexical types and grammar rules to enforce this.  So the first fixes were to ensure that our locative nominal suffix and negative adverb were fully constrained:
noun-loc-suffix-lex-rule :+ head-change-only-lex-rule.

scopal-mod-lex :+ [ SYNSEM.NON-LOCAL.YNQ 0-dlist ].

Next, we had to plug a hole in coordination:

unary-bottom-coord-rule :+
  [ SYNSEM [ NON-LOCAL.YNQ #ynq,
             L-PERIPH #periph ],
    ARGS < [ SYNSEM [ NON-LOCAL.YNQ #ynq,
                      L-PERIPH #periph ] ] > ].

Finally, we generalized a little bit from our previous types int-cl and decl-cl.  There was slight ambiguity when we did not constrain decl-cl to be [ YNQ 0-dlist ].  Also, there were many identical constraints between the two types and we wanted to make the grammar easily extendable if we wanted to introduce, for example, an imperative clause type imp-cl.  So we gathered the common constraints, including [ YNQ 0-dlist ], and created a supertype clause-top with subtypes int-cl and decl-cl (this also makes the difference between int-cl and decl-cl readily apparent):

clause-top := head-only &
  [ SYNSEM [ LOCAL.CAT [ VAL #val,
                         MC na ],
             NON-LOCAL.YNQ 0-dlist ],
    HEAD-DTR.SYNSEM [ LOCAL.CAT [ VAL #val,
                                  MC + ] ] ].

int-cl := clause-top & interrogative-clause &
  [ HEAD-DTR.SYNSEM.NON-LOCAL.YNQ <! *top* !> ].

decl-cl := clause-top & declarative-clause &
  [ HEAD-DTR.SYNSEM.NON-LOCAL.YNQ 0-dlist ].

These changes significantly reduced the ambiguity in our grammar.  The grammar we turned in for Lab 6 yielded an average of 6.76 parses per sentence over our test suite.  Making the above changes dropped the ambiguity to 3.63 parses per sentence.

VERB INFLECTION PIPELINE

The goal of our refactoring of the verb inflection pipeline this week was to create individual pipelines for all of our verb classes to reduce ambiguity:

vai, vii, vti, vta, vti-c (embedded clause), vta-c (embedded clause), copula-verb

The following have been refactored into individual pipelines:

vai, vii, vti, vta, and copula-verb (both animate and inanimate)

vti-c and vta-c use the default pipeline.

The following fragment demonstrates how this was done (using vii because it is one of the least extensive vis-a-vis morpheme rules):

;;;;;;;;
;;; VII
;;;;;;;;

verb-class-VII-verb-lex := vii-tense-rule-dtr & vii-negation-rule-dtr & vii-aspect-rule-dtr & intransitive-verb-lex & 
  [ INFLECTED -,
    SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.GEND inan ].

;;; VII Negation

vii-negation-rule-dtr := word-or-lexrule.

vii-negation-lex-rule := vii-tense-rule-dtr & infl-cont-change-only-ltol-rule & vii-aspect-rule-dtr &
  [ DTR vii-negation-rule-dtr ].


vii-negation-morph-lex-rule := vii-negation-lex-rule &
  [ C-CONT [ HOOK [ XARG #xarg,
                    LTOP #ltop,
                    INDEX #ind ],
             RELS <! event-relation &
                     [ PRED "_neg_r_rel",
                       LBL #ltop,
                       ARG1 #harg ] !>,
             HCONS <! qeq &
                      [ HARG #harg,
                        LARG #larg ] !> ],
    SYNSEM.LKEYS #lkeys,
    DTR.SYNSEM [ LKEYS #lkeys,
                 LOCAL [ CONT.HOOK [ XARG #xarg,
                                     INDEX #ind,
                                     LTOP #larg ],
                         CAT.HEAD verb ] ] ].


;;; VII Aspect

vii-aspect-rule-dtr := word-or-lexrule.

vii-aspect-lex-rule := vii-tense-rule-dtr & infl-add-only-no-ccont-ltol-rule &
  [ DTR vii-aspect-rule-dtr ].

vii-aspect-morph-1-lex-rule := vii-aspect-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.ASPECT habituality ].

vii-aspect-morph-2-lex-rule := vii-aspect-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.ASPECT begin ].

vii-aspect-morph-3-lex-rule := vii-aspect-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.ASPECT begin ].

vii-aspect-morph-4-lex-rule := vii-aspect-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.ASPECT end ].

vii-aspect-morph-5-lex-rule := vii-aspect-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.ASPECT end ].

vii-aspect-morph-6-lex-rule := vii-aspect-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.ASPECT end ].


;;; VII Tense

vii-tense-rule-dtr := word-or-lexrule.

vii-tense-lex-rule := infl-add-only-no-ccont-ltol-rule & vii-modal-rule-dtr & vii-person-prefix-rule-dtr &
  [ DTR vii-tense-rule-dtr ].

vii-verb-past-morph-lex-rule := vii-tense-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.TENSE past ].

vii-verb-future-morph-lex-rule := vii-tense-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.TENSE future ].

vii-verb-present-morph-lex-rule := vii-tense-lex-rule &
  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.E.TENSE present ].

;;; VII Modal Can

vii-modal-rule-dtr := word-or-lexrule.

vii-modal-lex-rule := infl-cont-change-only-ltol-rule & vii-person-prefix-rule-dtr &
  [ DTR vii-modal-rule-dtr ].

vii-modal-morph-lex-rule := vii-modal-lex-rule &
  [ C-CONT [ HOOK [ XARG #xarg,
                    LTOP #ltop,
                    INDEX #ind ],
             RELS <! event-relation &
                     [ PRED "_can_v_rel",
                       LBL #ltop,
                       ARG1 #harg ] !>,
             HCONS <! qeq &
                      [ HARG #harg,
                        LARG #larg ] !> ],
    SYNSEM.LKEYS #lkeys,
    DTR.SYNSEM [ LKEYS #lkeys,
                 LOCAL [ CONT.HOOK [ XARG #xarg,
                                     INDEX #ind,
                                     LTOP #larg ],
                         CAT.HEAD verb ] ] ].

;;; VII Prefix

vii-person-prefix-rule-dtr := word-or-lexrule.

vii-person-prefix-lex-rule := infl-add-only-no-ccont-ltol-rule & vii-modal-rule-dtr & vii-tense-rule-dtr &
  [ DTR vii-person-prefix-rule-dtr ].

vii-person-1-lex-rule := vii-person-prefix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.PERNUM 1st ].

vii-person-2-lex-rule := vii-person-prefix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.PERNUM 2nd ].

vii-person-3-lex-rule := vii-person-prefix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.PERNUM 3rd ].

vii-person-conj-lex-rule := vii-person-prefix-lex-rule &
  [ SYNSEM.LOCAL.CAT [ HEAD +vc,
                       MC - ] ].

;;; VII Person Suffix


vii-person-suffix-lex-rule := infl-ltow-rule & add-only-no-ccont-rule &
  [ DTR vii-person-prefix-lex-rule ].


vii-3SG-Prox-morph-1-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM SG,
                                                                GEND inan,
                                                                OBVIATION prox ] ].

vii-3SG-Obv-morph-1-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM SG,
                                                                GEND inan,
                                                                OBVIATION obv ] ].

vii-3PL-Prox-morph-1-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
                                                                GEND inan,
                                                                OBVIATION prox ] ].

vii-3PL-Prox-morph-2-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
                                                                GEND inan,
                                                                OBVIATION prox ] ].

vii-3PL-Obv-morph-1-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
                                                                GEND inan,
                                                                OBVIATION obv ] ].

vii-3SG-Obv-morph-2-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM SG,
                                                                GEND inan,
                                                                OBVIATION obv ] ].

vii-3PL-Prox-morph-3-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
                                                                GEND inan,
                                                                OBVIATION prox ] ].

vii-3PL-Obv-morph-2-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM PL,
                                                                GEND inan,
                                                                OBVIATION obv ] ].



;;; VII CONJ

vii-conj-3RD-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM 3RD,
                                                                GEND inan,
                                                                OBVIATION prox ] ].

vii-conj-3Obv-lex-rule := vii-person-suffix-lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM 3RD,
                                                                GEND inan,
                                                                OBVIATION obv ] ].

The changes to the pipeline helped reduced our distinct analysis for positive items to 2.24 from 6.71 in the previous lab.

IV.  GENERATION

We are still unable to generate from our grammar. Here are 5 sentences we attempted to generate from:

#12	
Source: author
Vetted: f
Judgment: g
Phenomena: agr
Giibizhaamgad jiimaanan
W-gii-bizhaamgak-0 jiimaan
3-PAST-come-3SG boat.IN.3SG
"The canoe came"

#14	
Source: author
Vetted: f
Judgment: g
Phenomena: agr
Waagosh waannose
Waagosh w-doo-waannosed-0
fox.AN.3SG 3-PRES-walk+in+a+circle.3SG
'The fox walks in a circle'

#16	
Source: author
Vetted: f
Judgment: g
Phenomena: agr
Nmamaa giizhitoon jiimaan
Nmamaa w-gii-zhitood-oo-n jiimaan
my+mother.AN.3SG 3-PAST-make-THM2.VTI-GL.SG boat.IN.3SG
'My mother made the boat'

#43	
Source: author
Vetted: f
Judgment: g
Phenomena: tam
Ngiimmaangshkiinzhgwe
N-gii-mmaangshkiinzhgwed-0
1SG-PAST-have+big+eyes.1SG
"I had big eyes"

#85	
Source: author
Vetted: f
Judgment: g
Phenomena: agr, pro-d
Giibizhaamgadnoon
W-gii-bizhaamgak-noon
3-PAST-come-3PL
"They (IN.3PL) came"


We have tried the complete sentences, selective edges from LKB charts, and parts of the sentence, all with no luck. Each attempt to generate requires killing emacs and reloading the lkb and our grammar. We are unsure of how to proceed, given the requirement that our grammar generate for week 9.


V.  COVERAGE OF LAB 6 AND LAB 7 GRAMMARS

Our focus on reducing ambiguity paid off this week, with a reduction of distinct analyses for both positive and negative items.


Total items: 358
Positive items: 237
Negative items: 121

Lab 6 Baseline
-------------------
Distinct positive analyses: 6.71
Total positive results: 207
Distinct negative analyses: 10.22
Total negative results: 18
COVERAGE: 87.3%
OVERGENERATION: 14.9%

Lab 7 Performance
-------------------
Distinct positive analyses: 2.24
Total positive results: 210
Distinct negative analyses: 3.00
Total negative results: 14
COVERAGE: 88.6%
OVERGENERATION: 11.6%
