Jason Shaw (author)
Prescott Klassen
LING 567
Lab 6
2/12/10

This writeup will be organized into four sections:
1. A summary of corrections made to the lab 5 grammar.
2. A descriptive statement of the grammatical facts of Nishnaabemwin.
3. A statement of how we implemented the phenomena for this week: embedded clauses, polar questions, and non-verbal predicates, including any unresolved problems in covering these phenomena.
4. A summary of the current coverage of the grammar over our test suite.

1. SUMMARY OF CORRECTIONS

	We changed our determiner rules so we could apply the _exists_q_rel on the determiner supertype and the demonstrative relation in the lexicon.

	determiner-lex-supertype := norm-hook-lex-item & basic-zero-arg &
	  [ SYNSEM [ LOCAL [ CAT [ HEAD det,
		       VAL[ SPEC.FIRST.LOCAL.CONT.HOOK [ INDEX #ind,
		                           LTOP #larg ],
		                        SPR < >,
		                        SUBJ < >,
		                        COMPS < >]],
		     CONT.HCONS < ! qeq &
		         [ HARG #harg,
		           LARG #larg ] ! > ],
		 LKEYS.KEYREL quant-relation &
		   [ ARG0 #ind,
		     RSTR #harg,
		     PRED "_exists_q_rel" ] ] ].

	Based on Go Post feedback, we also changed the COG-ST value to uniq+fam+act

	determiner-dem-prn-lex := determiner-lex-supertype &
	  [ SYNSEM [ LOCAL [ CAT.VAL.SPEC.FIRST.LOCAL.CONT.HOOK [ INDEX #ind & [COG-ST uniq+fam+act],
		                        LTOP #ltop ],
		                      CONT.RELS <! [] , #altkeyrel !> ] ,
		     LKEYS.ALTKEYREL #altkeyrel & [ ARG1 #ind, LBL #ltop ]]].

	Lexical entries were fixed and now follow this pattern:

	maaba := det-dem-prn-anim-3SGProx-determiner-lex &
	  [ STEM < "maaba" >,
	    SYNSEM.LKEYS.ALTKEYREL.PRED proximal+dem_a_rel ].

	Prenouns are now in the grammar as separate words. The default adejctive type from the Lab 5 instructions is implemented and the proper MRS and indexing is appearing in the parses. all grammatical sentences with adjectives now parse and all ungrammatical report either 0 or -1.

	Further examination of negation reveals that it is set up in the grammar correctly except for agreement, however some of our ungrammatical sentences are actually grammatical. Our Negative adverb is implemented as optional and sentence-initial.

2. THE FACTS OF NISHNAABEMWIN

	The following are the grammatical facts of Nishnaabemwin relevant through Lab 6:

	I. Verbs

		a. There are 4 main classes of verbs in Nishnaabemwin, each with their own inflectional paradigm:

			VAI - Intransitive verb with animate subject
			VII - Intransitive verb with inanimate subject
			VTA - Transitive verb with animate object
			VTI - Intransitive verb with inanimate object

		b. Verbs have 3 orders:
			- Independent (main clause)
			- Conjunct (wh-questions, sentential complements, etc.)
			- Imperative.

			We are covering independent order for matrix clauses and conjunct order for embedded clauses.

		c. Direct/Inverse

			VTA verbs in Nishnaabemwin are direct/inverse, which means that a suffix on the verb specifies the relation between the subject and object. We have incorporated direct/inverse into our VTA lexical rules.

		d. Inflection

			The verb carries a lot of information in Nishnaabemwin. It is inflected for person/gender/number (for both subject and object in transitive verbs), aspect, tense, negation, direct/inverse theme, and in order for independent and conjunct.

	II. Person/Number/Gender

		Nishnaabemwin has 1st, 2nd, 3rd, and unspecified actor persons. We cover 1st, 2nd and 3rd in our grammar. Number is singular or plural.  Gender is animate or inanimate. Nishnaabemwin also distinguishes between inclusive and exclusive first-person pluarl, but we do not cover this in our grammar.

	III. Other Features

		Nishnaabemwin nouns and inflection on verbs also reflect proximate and obviative relations to foregrounding and backgrounding of subject/object. Our grammar includes this other feature in our inflection of both nouns and verbs.  Additionally, nouns can take a locative suffix and be used in copular constructions to approximate what is accomplished with prepositional phrases in English.

	IV. Agreement

		Nouns and verbs agree in person, number, gender, and obviation.

	V. Prenouns

		"Prenoun" is a term our reference author uses to describe lexical items which attach to the fronts of nouns and behave syntactically like prefixes, yet are not subject to the same phonological processes as other types of prefixes.  We have chosen to treat prenouns as individual words instead of inflections on nouns. Semantically, prenouns are most like adjectives.

	VI. Demonstrative Pronouns

		There are no real determiners in Nishnaabemwin, no real way to say "the" or "a". We have chosen to classify demonstrative pronouns in Nishnaabemwin as determiners and demonstrative that describe distal relations between speaker and subject. There are three categories of distance, proximal, distal, and remote. Our demonstrative pronouns (classified as determiners) incorporate this into their semantics.

	VII. Negation

		There is a distinct adverb gaawii and a required verbal suffix that indicate negation. The adverb is optional, especially in casual usage, but the suffix is not.

	VIII. Yes/No

		The particle "na" is used for yes/no questions and must be in the second position in the sentence.  The item which precedes it is the item being questioned.  In our grammar we treat "na" as a clitic which assigns interrogative force to its clause.

	IX. Embedded Clauses

		Embedded clauses in Nishnaabemwin are indicated by an optional complementizer as well as distinct inflectional paradigms.  Embedded clauses normally follow the verbs which introduce them, but this is not always the case.

3. IMPLEMENTATION OF LAB 6 PHENOMENA

	I. Embedded clauses

		In Nishnaabemwin, all verb classes can potentially take a sentential complement. Intransitive verbs morph into transitives and transitive verbs that normally take only an animate or inanimate object complement, are able to take on a sentential complement instead.

		The inflection of the main verb may or may not agree with the main subject or object of the sentential complement. We have constrained our analysis to not require agreement and created our test sentences based on the most straightforward sample sentences in the reference grammar.

		The result is normal inflectional patterns for the main verbs (even though transitives -- both animate and inanimate -- inflect for 'missing' objects) and instead of selecting for an object, they select for [ HEAD +vc, MC- ].

		This new verb type is realized in the grammar in two forms (one for animate subject and one for inanimate subject):

		verb-class-VTI-C-verb-lex := tense-rule-dtr & negation-rule-dtr & aspect-rule-dtr & theme-rule-dtr & clausal-transitive-verb-lex &
		  [ INFLECTED -,
		    SYNSEM.LOCAL.CAT.MC + ].

		verb-class-VTA-C-verb-lex := tense-rule-dtr & negation-rule-dtr & aspect-rule-dtr & theme-rule-dtr & clausal-transitive-verb-lex &
		  [ INFLECTED -,
		    SYNSEM.LOCAL.CAT.MC + ].

		Both inherit from a new clausal-transitive-verb-lex:

		clausal-transitive-verb-lex := verb-lex & clausal-second-arg-trans-lex-item &
		  [ SYNSEM.LOCAL.CAT.VAL.COMPS < #comps >,
		    ARG-ST < [ LOCAL.CAT.HEAD noun ],
			     #comps &
			     [ LOCAL.CAT [ VAL [ SPR < >,
				                 COMPS < > ],
				           HEAD +vc,
				           MC - ] ] > ].

		Which select for a verb or comp (+vc) with MC-

		They also inherit all of the "slot" rules that enable them to be inflected like their non-clausal transitive twins.

		The lexicon contains both types of the same verb:

		gkendang := verb-class-VTI-verb-lex &
		  [ STEM < "gkendang" >,
		    SYNSEM.LKEYS.KEYREL.PRED "_know+something_v_rel" ].

		gkendang_2 := verb-class-VTI-C-verb-lex &
		  [ STEM < "gkendang" >,
		    SYNSEM.LKEYS.KEYREL.PRED "_know+something_v_rel" ].

		All complement sentential clauses are in conjunct order in Nishnaabemwin. This is an inflectional paradigm that is distinctly different from independent order, the required person prefix of independent is omitted and person is inflected as a suffix instead. Given this regular pattern, we added prefix and suffix rules that are specific to conjunct order and provide the right feature structures for them to be selected by main clauses:

		We are using the 0- morpheme to indicate missing person prefix in conjunct order:

		person-conj-lex-rule := person-prefix-lex-rule &
		  [ SYNSEM.LOCAL.CAT [ HEAD +vc,
				       MC - ] ].

		person-conj-prefix :=
		%prefix (* 0-)
		person-conj-lex-rule.

		Suffix rules provide additional constraints and follow the same pattern as our normal inflectional paradigms:

		vti-embd-SG-goalSG-morph-1-lex-rule := person-suffix-lex-rule &
		  [ SYNSEM.LOCAL.CAT.VAL [ SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG [ PERNUM SG,
				                                                  GEND anim,
				                                                  OBVIATION prox ],
				           COMPS.FIRST.LOCAL.CAT [ HEAD +vc,
				                                   MC - ] ] ].


		vti-embd-SG-goalSG-morph-1-suffix :=
		%suffix (* -n)
		vti-embd-SG-goalSG-morph-1-lex-rule.

		An example test sentence is:

		#196b   
		Source: author
		Vetted: f
		Judgment: g
		Phenomena: emb-d, adv
		ngiigkendaan wiimaajanid
		n-gii-gkendang-am-n 0-wii-maajaad-nid
		1SG-PAST-know+something-DIR.THM-3.OBV FUT-go+away-3.OBV.CONJ
		'I knew that they would go away'

		Additionally, an optional complementizer can be included in the sentence:

		; We treat question particles as complementizers.
		; Here is the lexical type for complementizers.

		complementizer-lex-item := raise-sem-lex-item & basic-one-arg &
		  [ SYNSEM.LOCAL.CAT [ HEAD comp &
				            [ MOD < > ],
				       VAL [ SPR < >,
				             SUBJ < >,
				             COMPS < #comp > ] ],
		    ARG-ST < #comp &
			     [ LOCAL.CAT [ MC -,
				           HEAD +vc,
				           VAL [ SUBJ < >,
				                 COMPS < > ] ] ] > ].

		; Subtype for question particles. Constrains SF to ques.

		qpart-lex-item := complementizer-lex-item &
		  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.SF ques ].

		ppart-lex-item := complementizer-lex-item &
		  [ SYNSEM.LOCAL.CONT.HOOK.INDEX.SF prop ].

		An example from the lexicon of a complementizer:

		maanda_p := ppart-lex-item &
		  [ STEM < "maanda" > ].

		In a sentence:

		#196c   
		Source: author
		Vetted: f
		Judgment: g
		Phenomena: emb-d, adv
		ngiigkendaan maanda wiimaajanid
		n-gii-gkendang-am-n maanda 0-wii-maajaad-nid
		1SG-PAST-know+something-DIR.THM-3.OBV that FUT-go+away-3.OBV.CONJ
		'I knew that they would go away'

		We also normalized our conjunct suffix inflections to simplify:

		Full theme + suffix suffix rules for VTI conjunct order and using first theme type as 'am' universal to all

		1s -> -aanh
		2s -> -an
		3s -> -g
		3' -> -nid
		1p -> -aang
		2p -> -eg
		3p -> -owaad

		One type (Nasal-final stem) suffix suffix rules for VAI conjunct order

		1s -> -aanh
		2s -> -an
		3s -> -g
		3' -> -nid
		1p -> -aang
		2p -> -eg
		3p -> -awaad

		One type suffix suffix rules for VII conjunct order

		3s -> -g
		3' -> -nig

		Full theme + suffix suffix rules for VTA conjunct order one theme only:

		1s -> 2s -inaan
		1s -> 3s -ag
		1s -> 3' -ag
		1s -> 2p -ininagog
		1s -> 3p -agwaa

		2s -> 1s -iyan
		2s -> 3s -ad
		2s -> 3' -ad
		2s -> 1p -iyaang
		2s -> 3p -adwaa

		3s -> 1s -id
		3s -> 2s -ik
		3s -> 3' -aad
		3s -> 1p -igoyaangid
		3s -> 2p -igoyeg

		3' -> 1s -id
		3' -> 2s -ik
		3' -> 3s -igod
		3' -> 1p -igoyaangid
		3' -> 2p -igoyeg
		3' -> 3p -igowaad

		1p -> 2s -igooyan
		1p -> 3s -aangid
		1p -> 3' -aangid
		1p -> 2p -igooyeg
		1p -> 3p -aangidwaa

		2p -> 1s -iyeg
		2p -> 3s -eg
		2p -> 3' -eg
		2p -> 1p -iyaang
		2p -> 3p -egwaa

		3p -> 1s -iwaad
		3p -> 2s -ikwaa
		3p -> 3' -aawaad
		3p -> 1p -igoyaangidwaa
		3p -> 2p -igoyegwaa

	II. Polar Questions

		Nishnaabemwin expresses polar questions by placing a clitic "na" immediately after the first word of the sentence.  Often, this constitues placing it after an NP, but when the NP uses a determiner, the particle intervenes:

		#151	
		Source: author
		Vetted: f
		Judgment: g
		Phenomena: q
		Gaag na zhiishiiban wminpawaawaan?
		Gaag na zhiishiib-an w-doo-mnopwaad-aa-an
		porcupine.AN.3SG QUES duck.AN-3.OBV AC.3SG-PRES-like+the+taste+of-DIR.THM-GL.3SG
		'Is it porcupines that like to eat ducks?'

		#154	
		Source: author
		Vetted: f
		Judgment: g
		Phenomena: q
		Maaba na nishnaabe moonshkwed?
		Maaba na nishnaabe w-doo-moonhashkiwed-0
		this.3SG.AN QUES Indian.AN.3SG 3-PRES-weed-SG
		'Is it this Indian who is weeding?'

		The word which precedes the clitic is the focused constituent in the sentences, the thing being questioned.  Our approach was to attach the question-marking clitic to the right of the sentence-initial word.  To keep track of whether a word is sentence-initial, we introduced a feature L-PERIPH:

		canonical-synsem :+
		  [ L-PERIPH bool ].

		To ensure that L-PERIPH is passed up in unary branching phrases, we added the constraints

		same-periph-unary-phrase := unary-phrase &
		  [ SYNSEM.L-PERIPH #periph,
		    ARGS < [ SYNSEM.L-PERIPH #periph ] > ].
		sub-clausal-unary-phrase := same-periph-unary-phrase & same-ynq-unary-phrase & mc-bool-headed-phrase.
		basic-head-opt-subj-phrase :+ sub-clausal-unary-phrase.
		basic-head-opt-comp-phrase :+ sub-clausal-unary-phrase.

		To ensure that only the left branch of a binary branching phrase can be marked L-PERIPH +, we also added

		basic-binary-phrase :+
		  [ SYNSEM [ L-PERIPH #periph,
			     NON-LOCAL.YNQ [ LIST #list,
					     LAST #last ] ],
		    ARGS < [ SYNSEM [ L-PERIPH #periph,
				      NON-LOCAL.YNQ [ LIST #list,
						      LAST #middle ] ] ],
			   [ SYNSEM [ L-PERIPH -,
				      NON-LOCAL.YNQ [ LIST #middle,
						      LAST #last ] ] ] > ].

		We also created a feature YNQ which stored whether the clitic was present (and therefore, whether the clause was interrogative).  We initialized it to be empty on all lexical items besides the clitic:

		non-local :+
		  [ YNQ 0-1-dlist ].
		basic-zero-arg :+ [ SYNSEM.NON-LOCAL.YNQ 0-dlist ].
		basic-one-arg :+ [ SYNSEM.NON-LOCAL.YNQ 0-dlist ].
		basic-two-arg :+ [ SYNSEM.NON-LOCAL.YNQ 0-dlist ].
		basic-three-arg :+ [ SYNSEM.NON-LOCAL.YNQ 0-dlist ].
		intersective-mod-lex :+ [ SYNSEM.NON-LOCAL.YNQ 0-dlist ].

		To pass this value up the tree, it is inherited directly in unary branching phrases:

		same-ynq-unary-phrase := unary-phrase &
		  [ SYNSEM.NON-LOCAL.YNQ #ynq,
		    ARGS < [ SYNSEM.NON-LOCAL.YNQ #ynq ] > ].

		And in binary branching phrases, the daughter lists are appended (see the constraints on basic-binary-phrase above).  Finally, we added rules which apply the appropriate sentential force to the clause:

		int-cl := head-only & interrogative-clause &
		  [ SYNSEM [ LOCAL.CAT [ VAL #val,
					   MC na],
			     NON-LOCAL.YNQ <! !> ],
		    HEAD-DTR.SYNSEM [ LOCAL.CAT [ MC bool,
						  VAL #val ],
				      NON-LOCAL.YNQ <! *top* !> ]].

		decl-cl := head-only & declarative-clause & same-ynq-unary-phrase &
		  [ SYNSEM.LOCAL.CAT [ VAL #val,
					 MC na ],
		    HEAD-DTR.SYNSEM [ LOCAL.CAT [ MC bool,
						  VAL #val ],
				      NON-LOCAL.YNQ 0-dlist ]].

		We also changed the root symbol to require [ MC na ] so that only sentences which have been given sentential force will be accepted.  Coupled with the creation of the type

		mc-bool-headed-phrase := headed-phrase &
		   [ SYNSEM.LOCAL.CAT.MC bool,
		     HEAD-DTR.SYNSEM.LOCAL.CAT.MC bool ].

		and the constraint

		binary-headed-phrase :+ mc-bool-headed-phrase.

		we ensure that non-root nodes will be [ MC bool ] and therefore that int-cl and decl-cl can only apply once, at the top of the tree.  With all of that machinery set up, we can create a new type of lexeme for our question clitic:

		question-clitic-lex := no-hcons-lex-item &
		  [ SYNSEM [ LOCAL [ CAT [ VAL [ SPR < >, COMPS < >, SUBJ < >, SPEC < >],
					   HEAD adv &
					       [ MOD < [ LIGHT +,
							 L-PERIPH +,
							 LOCAL intersective-mod ] > ]],
				     CONT.RELS <! !> ],
			     NON-LOCAL.YNQ <! *top* !> ]].

		This word establishes a non-empty YNQ which is then passed all the way up the tree until it is absorbed by int-cl, providing [ SF ques ] to the sentence.  As desired, it always appears second in the sentence, because it is specified as [ MOD < [ L-PERIPH + ] > ].  In order to avoid massive ambiguity, it was also necessary to constrain the value of MC within coordination structures.  To that end, we also added the constraints

		s-coord-phrase :+
		  [ SYNSEM.LOCAL.CAT.MC bool,
		    LCOORD-DTR.SYNSEM.LOCAL.CAT.MC bool,
		    RCOORD-DTR.SYNSEM.LOCAL.CAT.MC bool ].

		s-bottom-coord-phrase :+
		  [ SYNSEM.LOCAL.CAT.MC bool,
		    NONCONJ-DTR.SYNSEM.LOCAL.CAT.MC bool ].

	III. Non-verbal predicates

		Nishnaabemwin has no true adjectives, since all descriptions are accomplished with prenouns or stative verbs, so we did not need to analyze any predicative adjectives.  There is also nothing that could appropriately be called a preposition, so non-verbal PP predicates also seem to be no problem.  Prepositional concepts are expressed with prenouns, as well as with a special locative form of nouns.  The prenouns are optional and are used primarily to express quite specific prepositional concepts like "next to" or "under".  When general location is at issue, Nishnaabemwin simply uses one of a few copulas with locative semantics: "yaa", "bi", "te", and a few others.  These copulas are specified for gender: animate (yaa, bi, dgo) and inanimate (yaamgad, te, dgon).

		#245	
		Source: author
		Vetted: f
		Judgment: g
		Phenomena: cop
		Nmamaa yaa gaasmoonijiimaaning
		Nmamaa w-doo-yaa-0 gaasmoonijiimaan-ing
		my+mother be sailboat-LOC
		'My mother is on the sailboat'

		#255	
		Source: author
		Vetted: f
		Judgment: g
		Phenomena: cop, agr
		Nbabgiwyaan yaani jiimaaning
		Nbabgiwyaan w-doo-yaamgad-ni jiimaan-ing
		my+shirt be+located-3.SG.INAN.OBV
		'My shirt is on a boat'

		The first task was to create a basic type for copulas (for prepositional-like complements as well as NP complements):

		copula-verb-lex := transitive-verb-lex & tense-rule-dtr & negation-rule-dtr & aspect-rule-dtr &
		  [ SYNSEM.LOCAL.CAT.VAL.COMPS < [ OPT - ] >,
		    ARG-ST < [ LOCAL.CAT.HEAD noun ],
			     [ LOCAL.CAT.HEAD noun ] > ].

		Next we had to define a new feature for nouns that expressed whether it was locative, and create a lexical rule which could derive the locative form from the base form:

		noun :+ [ LOC bool ].
		noun-lex :+ [ SYNSEM.LOCAL.CAT.HEAD.LOC - ].
		noun-loc-suffix-lex-rule := inflecting-lex-rule & nocoord &
		  [ SYNSEM.LOCAL.CAT [ HEAD.LOC +,
				       VAL [ SPR #spr,
					     COMPS null ] ],
		    DTR [ SYNSEM.LOCAL.CAT [ HEAD.LOC -,
					     VAL.SPR #spr ],
			  INFLECTED + ] ].

		With these in hand, we could define a prepositional-like copula for Nishnaabemwin:

		copula-prep-verb-lex := copula-verb-lex &
		  [ SYNSEM.LOCAL [ CAT.VAL [ SUBJ < #subj >,
				             COMPS < #comps >,
				             SPR < >,
				             SPEC < > ],
				   CONT.HOOK.XARG #xarg ],
		    ARG-ST < #subj &
			     [ LOCAL [ CONT.HOOK.INDEX #xarg,
				       CAT [ VAL [ SPR < >,
				                   COMPS < > ],
				             HEAD noun ] ] ],
			     #comps &
			     [ LOCAL.CAT [ VAL [ COMPS < > ],
				           HEAD [ LOC + ] ] ] > ].
		.
		These copulas require their complement to be [ LOC + ], ensuring that they are only used with locative nouns.  To ensure that a locative noun is never a subject, we also added the constraint

		basic-head-subj-phrase :+
		  [ HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CAT.HEAD.LOC - ].

The analysis of "PP" predicates in Nishnaabemwin is not complete, as there are numerous examples of these copulas occurring with adverbial complements.  Additionally, while they are often used to express simple existence (as regular verbs), they can also be used intransitively to express the notion of "be here", and it is unclear whether that would be best analyzed as a null (or implied) adverbial complement, or as a distinct sense with a lemma like "_be+here_v_rel".  We have left examples like this out of our test suite for now.

		Next we analyzed NP predicates, or expressions of identity.  This was simpler because in Nishnaabemwin the copula for expressing identity between NPs is a normal transitive verb.  For various reasons, these copulas take intransitive inflection, so we were required to create a new type for them, but otherwise the analysis was quite straightforward.  Again the copula comes in an animate (aawi) and inanimate (aawan) form:

		copula-anim-subj-verb-lex := copula-verb-lex &
		  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.GEND anim ].
		copula-inan-subj-verb-lex := copula-verb-lex &
		  [ SYNSEM.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX.PNG.GEND inan ].

		Voila!

IV. COVERAGE OF LAB 5 AND LAB 6 GRAMMARS

The additions to the test suite this week were very successful.  Coverage of embedded clauses is 27/27, while overgeneration was only 4/22.  Coverage of polar questions is 9/9 and overgeneration is 0/5.  And coverage of non-verbal predicates is 12/17 while overgeneration is 4/12.  The following is the coverage and overgeneration for the lab 5 and lab 6 grammars:

Total items: 355
Positive items: 234
Negative items: 121

Lab 5 Baseline
-------------------
Distinct positive analyses: 3.55
Total positive results: 159
Distinct negative analyses: 3.14
Total negative results: 14
COVERAGE: 67.9%
OVERGENERATION: 11.6%

Lab 6 Performance
-------------------
Distinct positive analyses: 6.76
Total positive results: 206
Distinct negative analyses: 10.22
Total negative results: 18
COVERAGE: 88.0%
OVERGENERATION: 14.9%
